VisualG Procedimentos no Visu Alg

[Lorenzo Nunez]

Olá, estou enfrentado problemas neste código, ele apresenta um erro que não consegui decifrar. 

 

Algoritmo "Procedimentos"
// Disciplina  : Algoritmos
// Professor   : Livro Algoritmos
// Descrição   : Excercios do Livro
// Autor(a)    : Lorenzo Nunez
// Data atual  : 10/11/2022
Const
   fim = 10
Var
// Seção de Declarações das variáveis
   vetA: vetor[1..fim] de caractere

Procedimento Entrada
Var
   i: inteiro
Inicio
   para i de 1 ate fim faca
      escreva("Digite o",i,"º: ")
      leia(vetA[i])
   fimpara
Fimprocedimento

Procedimento Processamento
   Procedimento Troca (var a, b: caractere)
   Var
   x: caractere
   Inicio
      x <- a
      a <- b
      b <- x
   Fimprocedimento
   Procedimento Ordenacao
   Var
      i, j: inteiro
   Inicio
      para i de 1 ate fim-1 faca
         para j de i+1 ate fim faca
            se (vetA[i] > vetA[j]) então
               Troca(vetA[i],vetA[j])
            fimse
         fimpara
      fimpara
   Fimprocedimento
Inicio
   Ordenacao()
Fimprocedimento

Procedimento Saida
Var
   i: inteiro
Inicio
   para i de 1 ate fim faca
      escreval("[",vetA[i]," ]")
   fimpara
Fimprocedimento

Inicio
// Seção de Comandos, procedimento, funções, operadores, etc... 
   Entrada()
   Processamento()
   Saida()

Fimalgoritmo

 

[Simon Viegas]

Em 10/11/2022 às 12:39, Lorenzo Nunez disse:

Olá, estou enfrentado problemas neste código, ele apresenta um erro que não consegui decifrar. 

 

"Um" erro? Aí não ajuda! Qual erro está dando? 

 

 

Adendo:
Para adiantar... não lembro se o VisualG aceita "procedimento dentro de procedimento". Daí, deixe separados.. (não vai fazer diferença). Exemplo:

Algoritmo "Procedimentos"
// Disciplina  : Algoritmos
// Professor   : Livro Algoritmos
// Descrição   : Excercios do Livro
// Autor(a)    : Lorenzo Nunez
// Data atual  : 10/11/2022
Const
   fim = 10
Var
   vetA: vetor[1..fim] de caractere

Procedimento Entrada
Var
   i: inteiro
Inicio
   para i de 1 ate fim faca
      escreva("Digite o",i,"º: ")
      //leia(vetA[i])
      vetA[i] <- Carac(Asc("A") + RandI(9)+1)
      escrevaL(vetA[i])
   fimpara
Fimprocedimento

Procedimento Troca (var a, b: caractere)
Var
   x: caractere
Inicio
   x <- a
   a <- b
   b <- x
Fimprocedimento

Procedimento Ordenacao
Var
   i, j: inteiro
Inicio
   para i de 1 ate fim-1 faca
      para j de i+1 ate fim faca
         se (vetA[i] > vetA[j]) então
            Troca(vetA[i],vetA[j])
         fimse
      fimpara
   fimpara
Fimprocedimento

Procedimento Processamento
Inicio
   Ordenacao()
Fimprocedimento


Procedimento Saida
Var
   i: inteiro
Inicio
   para i de 1 ate fim faca
      escreval("[",vetA[i]," ]")
   fimpara
Fimprocedimento

Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...
   Entrada()
   Processamento()
   Saida()
Fimalgoritmo

 

[Lorenzo Nunez]

Em 11/11/2022 às 17:01, Simon Viegas disse:

"Um" erro? Aí não ajuda! Qual erro está dando? 

 

 

Adendo:
Para adiantar... não lembro se o VisualG aceita "procedimento dentro de procedimento". Daí, deixe separados.. (não vai fazer diferença). Exemplo:

Algoritmo "Procedimentos"
// Disciplina  : Algoritmos
// Professor   : Livro Algoritmos
// Descrição   : Excercios do Livro
// Autor(a)    : Lorenzo Nunez
// Data atual  : 10/11/2022
Const
   fim = 10
Var
   vetA: vetor[1..fim] de caractere

Procedimento Entrada
Var
   i: inteiro
Inicio
   para i de 1 ate fim faca
      escreva("Digite o",i,"º: ")
      //leia(vetA[i])
      vetA[i] <- Carac(Asc("A") + RandI(9)+1)
      escrevaL(vetA[i])
   fimpara
Fimprocedimento

Procedimento Troca (var a, b: caractere)
Var
   x: caractere
Inicio
   x <- a
   a <- b
   b <- x
Fimprocedimento

Procedimento Ordenacao
Var
   i, j: inteiro
Inicio
   para i de 1 ate fim-1 faca
      para j de i+1 ate fim faca
         se (vetA[i] > vetA[j]) então
            Troca(vetA[i],vetA[j])
         fimse
      fimpara
   fimpara
Fimprocedimento

Procedimento Processamento
Inicio
   Ordenacao()
Fimprocedimento


Procedimento Saida
Var
   i: inteiro
Inicio
   para i de 1 ate fim faca
      escreval("[",vetA[i]," ]")
   fimpara
Fimprocedimento

Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...
   Entrada()
   Processamento()
   Saida()
Fimalgoritmo

 

 

Muito obrigado pela ajuda, realmente o problema estava no procedimento dentro de outro. S2.