Portugol Não sei como resolver essa questão de Repetição Enquanto, Portugol Studio

[Paulo_Assunção]

Sou iniciante na programação e estou resolvendo exercícios de lógica, uso o Portugol Studio para isso, alguém poderia me ajudar a resolver esse exercício:

Desenvolva um programa que faça o sorteio de 20 números entre 0 e 10 e mostre na tela:

a) Quais foram os números sorteados

b) Quantos números estão acima de 5

c) Quantos números são divisíveis por 3

 

Irei deixar o que escrevi até agora, mas acredito que esteja errado pois não é exatamente o que a questão está pedindo:

 

programa
{
     inclua biblioteca Util --> bp 
    inteiro num
    
    funcao inicio()
    {
        inteiro cont_num = 0
        escreva("==================================\n")
        escreva("EXERCÍCIOS DE REPETIÇÕES ENQUANTO\n")
        escreva("==================================\n")
        enquanto(cont_num <= 9)
        {
            cont_num = (cont_num + 1)
            num = bp.sorteia(0, 20)    
            escreva("NÚMERO GERADO: ",num,"\n")
            se(num > 5)
            {
                escreva("NÚMERO MAIOR QUE CINCO.\n")
            }
            se(num % 3 == 0)
            {
                escreva("NÚMERO DIVISÍVEL POR TRÊS.\n")
            }
            escreva("==================================\n")
        }
    }
} 

 

[Simon Viegas]

16 horas atrás, Paulo_Assunção disse:

Irei deixar o que escrevi até agora, mas acredito que esteja errado pois não é exatamente o que a questão está pedindo:

 

Justamente. Faça o que ele pede... ele quer "quantos", não "quais". Basicamente é precisado se atentar ao problema, ou seja: aquilo que estaria sendo pedido no enunciado.

 

As alterações são simples... segue um exemplo de código:

 

programa
{
	inclua biblioteca Util --> u
	
	funcao inicio()
	{
		inteiro num, cont_num = 1, qtd_acima_de_5 = 0, qtd_divisiveis_por_3  = 0

		escreva("==================================\n")
		escreva("EXERCÍCIOS DE REPETIÇÕES ENQUANTO \n")
		escreva("==================================\n")
		
		enquanto(cont_num <= 20)
		{
			num = u.sorteia(0, 10)			
			escreva("NÚMERO GERADO: ", num, "\n")
			
			se (num > 5)
			{
				qtd_acima_de_5++
			}
			
			se (num % 3 == 0)
			{
				qtd_divisiveis_por_3++
			}
			cont_num++
		}

		escreva("\nQuantidade de números acima de 5    : ", qtd_acima_de_5, "\n")
		escreva("Quantidade de números divisíveis por 3: ", qtd_divisiveis_por_3, "\n")
	}
}

 

[Paulo_Assunção]

@Simon Viegas Muito obrigado! Pelo seu código eu pude ver exatamente onde estava errando e já consegui resolver vários exercícios parecidos, mas que eu estava empacado por não saber como mostrar "quantos" valores.