VisualG Faça o pseudocódigo para escrever a tabuada do números de 2 a 9

[annabanana]

Preciso resolver esse exercício, mas estou com dúvida se estou fazendo da forma correta.

algoritmo "tabuada para faca"
// Função :
// Autor :
// Data : 25/09/2018
// Seção de Declarações 
var
n,cont,prod:inteiro
inicio
// Seção de Comandos
escreva("digite o valor de n")
leia(n)
escreval("tabuada de ",n)
para cont de 2 ate 9 passo 1 faca
prod<-cont*n
escreval(n,"X",cont,"=",prod)
cont<-cont+1
fimpara
fimalgoritmo

 

[devair1010]

@annabanana      para postar seu código é melhor usar o botão   <>  que está lá na barra de ferramentas da janela de postar pois senão seu código fica faltando alguns caracteres ,  e seu código está certo , apenas que no comando leia seria bom se informasse o que o usuário deve digitar , por exemplo  :

escreval("Digite Qual Casa Da Tabuada ")

por que o valor de n não se sabe a que se refere  .

[Simon Viegas]

Olá.

 

1#

Para postar um código, clique antes no botão <> que fica na barra de ferramentas.

 

 

 

2#

@annabanana, poste o enunciado completo para analisarmos melhor.

 

 

 

3#

Para adiantar, segue alguns pontos para serem revistos:

algoritmo "FCdH"
var
   n, cont, prod :inteiro
inicio
escreva ("Digite o valor de n :")
leia(n)
escreval("Tabuada de",n)
{para cont de 2 ate 9 passo 1 faca}
//começa do 1; vai até o 10; para de 1 em 1 não precisa do "passo"
para cont de 1 ate 10 faca
   prod<-cont*n
   escreval(n," x",cont:3," =",prod)
   {cont<-cont+1} //quem controla o passo é o para
fimPara
fimAlgoritmo

 

Aí ainda entra outros pontos:

• como a questão citada por @devair1010 de contextualizar o que seria o n;
• a necessidade ou não da variável prod, já que a conta poderia ser feita diretamente no escreval();
• A parte fixa fica antes ou fica depois? ex.: n=3 é 3x1 ou 1x3?

Mas o que falta principalmente é o enunciado completo... para assim verificar quais características o programa deve se basear.

 

No aguardo.

[annabanana]

A questão está completa, (6- Faça o pseudocódigo para escrever a tabuada do números de 2 a 9), por isso tive dificuldade de entender.

[Simon Viegas]

1#

Sobre:

10 horas atrás, annabanana disse:

A questão está completa, (6- Faça o pseudocódigo para escrever a tabuada do números de 2 a 9), por isso tive dificuldade de entender.

 

Certo, a primeira coisa a se fazer é saber o que é uma tabuada. Creio que todos tem uma noção... mas dando uma pesquisada rápida, vemos que tem, pelo menos, tabuadas de adição e multiplicação. Tem tabelas em colunas e em quadro. Ex.:

 

 

 

É de adição ou multiplicação?

É de coluna ou em quadro?

 

Entende? fica complicado desenvolver um algoritmo de algo que não está definido. Acertar seria sorte (talvez minimizada pelo "bom senso da probabilidade")... ou podendo considerar o enunciado como "aberto"...

 

Perceba por exemplo que a resposta de @devair1010 se refere ao código que foi postado... já que não tinha o enunciado. Ele sugere que utilize uma "frase mais explicativa na hora de ler o valor de n" , mas como verificável, não é necessário ler o valor de n, pois ele já foi explicitamente definido. Se ele É de 2 a 9, vou ler o quê?

 

Resumindo:

Vamos tomar por base que será uma tabuada de multiplicação e que usará uma tabela por colunas, ou seja, cada valor de n será uma tabela.

 

 

 

2#

Para demonstrar, utilizei outro exemplo de nomenclaturas para as variáveis. Os nomes das variáveis podem ser variados... mas é recomendo utilizar algo que remete a sua funcionalidade, como no exemplo abaixo. Poderia também ser M e N... ou N1 e N2... ou mesmo o n e cont.

 

Uma primeira tabuada poderia ficar com algo  assim.

algoritmo "FCdH"
var
   multiplicando, multiplicador:inteiro
inicio
multiplicando <- 2
escreval("Tabuada de",multiplicando)
para multiplicador de 1 ate 10 faca
   escreval(multiplicando," x",multiplicador:3," =",multiplicando*multiplicador)
fimPara
fimAlgoritmo

 

 

 

3#

Como faz para o outros números? só replicar:

algoritmo "FCdH"
var
   multiplicando, multiplicador:inteiro
inicio
multiplicando <- 2
escreval("Tabuada de",multiplicando)
para multiplicador de 1 ate 10 faca
   escreval(multiplicando," x",multiplicador:3," =",multiplicando*multiplicador)
fimPara
escreval()
multiplicando <- 3
escreval("Tabuada de",multiplicando)
para multiplicador de 1 ate 10 faca
   escreval(multiplicando," x",multiplicador:3," =",multiplicando*multiplicador)
fimPara
escreval()
multiplicando <- 4
escreval("Tabuada de",multiplicando)
para multiplicador de 1 ate 10 faca
   escreval(multiplicando," x",multiplicador:3," =",multiplicando*multiplicador)
fimPara







fimAlgoritmo

 

 

 

4#

"Ah! mas código ficou repetitivo". Verdade. Mas está correta e funciona. Não foi limitado isso no enunciado!

 

Então, mas como já está utilizando laços de repetições (para) no código, faria mais sentido utilizar OUTRO laço para evitar essa repetição. Além das definições citadas no próprio enunciado, o contexto da questão também pode contar..., ou seja, possivelmente esse exercício está num módulo de estudos de laços de repetições... ou mesmo que foi proposto após já ter estudados eles, logo, fica subentendido que de fato "deveria" ser feito com laços. Em outras palavras, o objetivo do programa não é apenas ter uma resposta válida (como seria via estrutura do código anterior), mas sim treinar o que está estudando no momento (em conjunto com o que já estudou, é claro).

 

 

Resumindo:

Perceba que o quê varia de uma tabela para a outra é somente o valor do multiplicando. Logo, poderia criar um outro para para fazer o multiplicando variar na faixa correspondente (no caso de 2 a 9). Aí o para do multiplicador fica dentro do para do multiplicando.

 

 

***

 

Tenta implementar o código e posta aqui para analisarmos. Se tiver dúvida, é só informar também.

 

No aguardo.