VisualG é possivel arredondar um numero no visualg ?

[Semnet]

Tava fazendo um exercicio relacionado a escola e para ser aprovado deveria tirar 7 mas ficou com 6.75 . Ai fiquei curioso para saber se da para arredondar um numero , se sim como faz ?

[Luís Roberto C. da Silva]

É só fazer condicionais:

Se nota > 6 E nota <= 7 entao
  nota = 7

 

[Simon Viegas]

Duas outras formas:

 

- Convertendo para inteiro;

- Usando formatação de número reais (só consegui servido para imprimir direto na tela).

 

Ex.:

algoritmo "media"
var
   numReal :real
   numArredondado: inteiro

inicio
   //2 exemplos convertendo para inteiro
   escrevaL("Arredondando usando Int()")
   escreval("")
   numReal <- 6.75
   numArredondado <- int(numReal + 0.5) //aqui dá para copiar o valor arredondado
   escreval("Valor original   :", numReal)
   escreval("Valor arredondado:", numArredondado) //vai imprimir 7
   escreval("")
   numReal <- 6.49
   numArredondado <- int(numReal + 0.5)
   escreval("Valor original   :", numReal)
   escreval("Valor arredondado:", numArredondado) //vai imprimir 6
   escreval("")
   escreval("")

   //2 exemplos formatando um número real
   escrevaL("Arredondando utilizando formatação (apenas visual)")
   escreval("")
   numReal <- 6.75
   escreval("Valor original   :", numReal)
   escreval("Valor arredondado:", numReal:2:0) //vai imprimir 7 (não dá para copiar o valor, mas dá para exibir na tela)
   escreval("")
   numReal <- 6.49
   escreval("Valor original   :", numReal)
   escreval("Valor arredondado:", numReal:2:0) //vai imprimir 6
fimAlgoritmo

 

Resultado:

 

 

adicionado 8 minutos depois

Adendo:

Sobre:

Em 30/09/2019 às 18:13, Luís Roberto C. da Silva disse:

É só fazer condicionais:

Se nota > 6 E nota <= 7 então
  nota = 7

 

Tem 2 pontos:

- como são duas sentenças, precisa dos ();

- depende do arredondamento. Geralmente é a partir de .5 aproxima para cima, abaixo aproxima para baixo. Ex.:

se (nota >= 6.5) e (nota < 7.5) então
  nota = 7
fimSe

De qualquer forma, aí teria que ter um se para cada possibilidade de números.