VisualG alguem poderia me ajudar a fazer esse programa ?

Eric Fernandes · 9 de abril de 2020

Petrópolis é um município localizado na Região Metropolitana do Rio de Janeiro. Ocupa uma área de 795,798 km², sua população no ano de 2018 era de 305 687 habitantes segundo a estimativa do IBGE. Teresópolis é um município localizado no interior do estado do Rio de Janeiro. Ocupa uma área de 770,601 km², sendo que 11,3400 km² estão em perímetro urbano. Sua população, conforme estimativas do IBGE de 2018, era de 180 886 habitantes. Vamos supor que Petrópolis tenha um crescimento populacional estimado de 5% ao ano e que Teresópolis 7,3%. Neste cenário e imaginando que este crescimento seja constante, faça um algoritmo que apresente daqui a quantos anos Teresópolis terá mais habitantes que Petrópolis? Quantos habitantes cada cidade terá neste cenário? E qual é a relação área/habitante (Densidade demográfica) de cada cidade hoje e no “futuro”?

Simon Viegas · 9 de abril de 2020

Caro usuário,

Seja bem-vindo ao Fórum do Clube do Hardware.

No intuito de servir como fonte de pesquisa no caso de instituições de ensino, informamos que incorrer no resolvimento por completo de questões relacionadas a disciplinas escolares de cursos técnicos e faculdades podem ser revistas e removidas pela Equipe de Moderação do Clube do Hardware.

Para sanar dúvidas sobre esse tipo de problema, por gentileza, publique o passo a passo do desenvolvimento da questão, projeto, monografia ou conteúdo em dúvida para que possamos analisar se a resposta está correta ou não, ou para que possa ser auxiliado com a dúvida no desenvolvimento do exercício.

Infelizmente, não há como resolver os trabalhos pelos usuários. O objetivo do Fórum do Clube do Hardware é auxiliar seus usuários a encontrar soluções para que possam sanar suas dúvidas, e não de trazer soluções prontas para seus usuários. Além disso, copiar e colar respostas que não são de autoria própria do qualquer usuário é considerado plágio, o que é ilegal.

Esperamos que compreenda.

Atenciosamente,

Equipe Clube do Hardware

HumanProject01 · 9 de abril de 2020

@Eric Fernandes Vou te dar o caminho. Faça uma estrutura de repetição, colocando como calculo os acréscimos de porcentagem de cada região a cada ano. A estrutura de repetição irá percorrer seu algoritmo e gerar resultados até quando você decidir, por exemplo percorra o algoritmo e faça o calculo 10 vez ou enquanto(WHILE) X for maior que Y percorra Y. O caminho é Estrutura de repetição, fará você achar o resultado esperado.

Eric Fernandes · 9 de abril de 2020

@HumanProject01, eu consegui fazer esse algoritmo, mas ele não para de gerar números e nunca acha quando Teresópolis será maior que Petrópolis, podia me dar uma luz no que está errado?

var
pet,ter, tax, total : real
inicio
pet<- 305687
tax<- 0.05
ter<- 180886
tax<- 0.073
enquanto pet > ter faca
   total<- pet*tax+pet
   pet<-total
   total<- ter*tax+ter
   ter<-total
   limpatela
   escreval (" A população prevista é de petropolis : ",pet:2:0," Hab")
   escreval (" A população prevista é de teresopolis : ",ter:2:0," Hab")

HumanProject01 · 10 de abril de 2020

@Eric Fernandes, até peguei seu código para completar. O escreval primeiramente tem que ficar depois do fim enquanto. E crie um contador que contará os anos. E separe as taxas, crie duas variáveis de taxa já que cada uma tem uma valor. Ex: tax_petropolis, tax_teresopolis

var
petropolis,teresopolis, tax_petro, tax_tere, total : real
cont: inteiro
inicio
petropolis<- 305687
tax_petro<- 0.05
teresopolis<- 180886
tax_tere<- 0.073
cont <- 1
           enquanto teresopolis < petropolis faca
           total<- teresopolis*tax_tere + teresopolis
           teresopolis<- total
           cont <- cont + 1
 
               Fimenquanto
   limpatela
   escreval (" A população prevista teresopolis: ", teresopolis:2:0," Hab")
   escreval ("contador será: ", cont)

OBS.: NÃO ESTÁ COMPLETO, você vai rodar, vai aparecer a população prevista e o ano que teresopolis passará petropolis, mas não fiz o calculo de petropolis, deixarei para você fazer. Porque assim como teresopolis, petropolis também tem um aumento, mas sem o cálculo de aumento, suponha que petropolis não tenha aumentado, nesse caso teresopolis passa petropolis em 9 anos, o ''cont'' informa isso. Agora basta só dentre esses 9 anos aplicar o aumento de Petropolis para saber o resultado final.

Simon Viegas · 10 de abril de 2020

@Eric Fernandes, segue algumas dicas iniciais gerais:

Manter as estruturas da sintaxe sempre completas;
Manter o código identado;
Utilizar nomenclaturas de variáveis mais sugestíveis;
Implementar o algoritmo aos poucos.

Vamos lá:

Umas dicas iniciais é sempre manter as estruturas do código completas e manter o código identado. Exemplo:

algoritmo "Aqui um nome do programa" //faltou

var
   petropolis, teresopolis : real
   tax_petro, tax_tere : real
   total : real
   cont: inteiro

inicio
   petropolis <- 305687
   tax_petro <- 0.05
   teresopolis <- 180886
   tax_tere <- 0.073
   cont <- 1
   enquanto teresopolis < petropolis faca
      total <- teresopolis + teresopolis*tax_tere
      teresopolis <- total
      cont <- cont + 1
   fimEnquanto
   limpaTela
   escreval (" A população prevista teresopolis: ", teresopolis:1:0," Hab")
   escreval ("contador será: ", cont)
   
   
   
fimAlgoritmo //faltou

O VisualG tem um "identador automático"... basta pressionar CTRL+G.

Outra dica bacana é colocar o enunciado no próprio código antes de começar a implementar. Por exemplo:

algoritmo "Exercício 00X"
// Disciplina  :
// Professor   :
// Descrição   : Petrópolis é um município localizado na Região Metropolitana
//   do Rio de Janeiro. Ocupa uma área de 795,798 km², sua população no ano
//   de 2018 era de 305 687 habitantes segundo a estimativa do IBGE.
//   Teresópolis é um município localizado no interior do estado do Rio de
//   Janeiro. Ocupa uma área de 770,601 km², sendo que 11,3400 km² estão em
//   perímetro urbano. Sua população, conforme estimativas do IBGE de 2018,
//   era de 180 886 habitantes. Vamos supor que Petrópolis tenha um crescimento
//   populacional estimado de 5% ao ano e que Teresópolis 7,3%. Neste cenário
//   e imaginando que este crescimento seja constante, faça um algoritmo que
//   apresente daqui a quantos anos Teresópolis terá mais habitantes que
//   Petrópolis? Quantos habitantes cada cidade terá neste cenário? E qual é a
//   relação área/habitante (Densidade demográfica) de cada cidade hoje e no
//   "futuro"?
// Autor(a)    : Eric Fernandes
// Data atual  : 10/04/2020
  
inicio

   
   
fimAlgoritmo

Daí, fica mais fácil para consultar. A ideia é implementando de acordo que vai assimilando do enunciado...

Outra dica é em relação às nomenclaturas das variáveis... assim como proposto por @HumanProject01, só que ainda poderiam ser mais sugestíveis, exemplo:

var
   populcaoPetropolis, populacaoTeresopolis : real
   taxaCrescimentoPetropolis, taxaCrescimentoTeresopolis : real
   novaPopulacao : real
   qtdAnos: inteiro

Poderia abreviar também:

var
   popPetropolis, popTeresopolis : real
   txCrescPetropolis, txCrescTeresopolis : real
   novaPopulacao : real
   qtdAnos: inteiro

Percebam que sem mesmo saber qual seria o contexto dessas variáveis, dá para meio que ter um noção para quê elas vão servir...

Outro ponto seria em implementar o algoritmo por partes... por exemplo, só implementar e testar quando a população de uma cidade vai ultrapassar o da outra, exemplo:

algoritmo "Exercio 00X"
// Disciplina :
// Professor  :
// Descrição  : Petrópolis é um município localizado na Região Metropolitana
//   do Rio de Janeiro. Ocupa uma área de 795,798 km², sua população no ano
//   de 2018 era de 305 687 habitantes segundo a estimativa do IBGE.
//   Teresópolis é um município localizado no interior do estado do Rio de
//   Janeiro. Ocupa uma área de 770,601 km², sendo que 11,3400 km² estão em
//   perímetro urbano. Sua população, conforme estimativas do IBGE de 2018,
//   era de 180 886 habitantes. Vamos supor que Petrópolis tenha um crescimento
//   populacional estimado de 5% ao ano e que Teresópolis 7,3%. Neste cenário
//   e imaginando que este crescimento seja constante, faça um algoritmo que
//   apresente daqui a quantos anos Teresópolis terá mais habitantes que
//   Petrópolis? Quantos habitantes cada cidade terá neste cenário? E qual é a
//   relação área/habitante (Densidade demográfica) de cada cidade hoje e no
//   "futuro"?
// Autor(a)   :
// Data atual : 10/04/2020

var
   popPetropolis, popTeresopolis : real
   txCrescPetropolis, txCrescTeresopolis : real
   //areaPetropolis, areaTeresopolis : real
   //densDemoPetropolisAtual, densDemoTeresopolisAtual : real
   //densDemoPetropolisNova, densDemoTeresopolisNova : real

   qtdAnos: inteiro

inicio
   popPetropolis      <- 305687
   txCrescPetropolis  <- 0.05
   popTeresopolis     <- 180886
   txCrescTeresopolis <- 0.073
   qtdAnos <- 0

   enquanto (popTeresopolis < popPetropolis) faca
      qtdAnos <- qtdAnos + 1
      popPetropolis  <- popPetropolis  + popPetropolis * txCrescPetropolis
      popTeresopolis <- popTeresopolis + popTeresopolis * txCrescTeresopolis
   fimEnquanto

   escreval("Após ", qtdAnos:1:0, " anos, a população de Teresópolis será maior que a população de Petrópolis")
   
fimAlgoritmo

Por ai vai...

Você precisa fazer este 3 itens:

Daqui a quantos anos Teresópolis terá mais habitantes que Petrópolis? (exemplo já adiantado acima)
Quantos habitantes cada cidade terá neste cenário? ("neste cenário" = "no ano que Teresópolis ultrapassou Petrópolis")
E qual é a relação área/habitante (Densidade demográfica) de cada cidade hoje e no “futuro”?

Eric Fernandes · 10 de abril de 2020

@HumanProject01 e @Simon Viegas, muito obrigado pela ajuda. Consegui fazer o trabalho e ficou do jeito que eu queria.

Ótima pagina, continue com esse trabalho estão ajudando muita gente.

algoritmo "trabalho de algoritmos dever 2 "
// Autor : Eric fernandes da costa
// Data : 10/04/2020

var
   popPetropolis, popTeresopolis : real
   txCrescPetropolis, txCrescTeresopolis : real
   areaPetropolis, areaTeresopolis : real
   densDemoPetropolisAtual, densDemoTeresopolisAtual : real
   densDemoPetropolisNova, densDemoTeresopolisNova : real
   qtdAnos: inteiro

inicio
   popPetropolis      <- 305687
   txCrescPetropolis  <- 0.05
   popTeresopolis     <- 180886
   txCrescTeresopolis <- 0.073
   qtdAnos <- 0
   densDemoPetropolisAtual <- popPetropolis/795798
   densDemoTeresopolisAtual <- popTeresopolis/770601

   enquanto (popTeresopolis < popPetropolis) faca
         qtdAnos <- qtdAnos + 1
         popPetropolis  <- popPetropolis  + popPetropolis * txCrescPetropolis
         popTeresopolis <- popTeresopolis + popTeresopolis * txCrescTeresopolis
         densDemoPetropolisNova <- popPetropolis/795798
         densDemoTeresopolisNova <- popTeresopolis/770601

   fimEnquanto
   escreval ("<><><><><><><><><><><><><><><><><><><><><><><><><><>")
   escreval("A densidade demografica de petropolis atualmente é:",densDemoPetropolisAtual )
   escreval ("<><><><><><><><><><><><><><><><><><><><><><><><><><>")
   escreval("A densidade demografica de teresopolis atualmente é:",densDemoTeresopolisAtual )
   escreval ("<><><><><><><><><><><><><><><><><><><><><><><><><><>")
   escreval("A densidade demografica de petropolis no futuro sera:",densDemoPetropolisNova)
   escreval ("<><><><><><><><><><><><><><><><><><><><><><><><><><>")
   escreval("A densidade demografica de teresopolis no futuro sera:",densDemoTeresopolisNova)
   escreval ("<><><><><><><><><><><><><><><><><><><><><><><><><><>")
   escreval ("petropolis tera em 25 anos a popuçaçao de", popPetropolis)
   escreval ("<><><><><><><><><><><><><><><><><><><><><><><><><><>")
   escreval ("teresopolis tera em 25 anos a popuçaçao de", popTeresopolis)
   escreval ("<><><><><><><><><><><><><><><><><><><><><><><><><><>")
   escreval("Após ", qtdAnos:1:0, " anos, a população de Teresópolis será maior que a população de Petrópolis")

fimAlgoritmo

Assim ficou o algoritmo

Simon Viegas · 10 de abril de 2020

@Eric Fernandes, alguns pontos:

Você está calculando a densidade demográfica várias vezes sem necessidade. Só precisa (deve) ser feito apenas uma vez (depois do fimEnquanto);
O resultado final achei que ficou muito poluído... sugiro tirar essas linhas com "<>". Pelo menos as que estão entre as linhas;
Os valores dos resultados finais estão saindo com muitas casas decimais. Utilize uma formatação, por exemplo utilizando 1:3 após as variáveis do tipo real, ex.: densDemoPetropolisAtual:1:3. (obs.: corrija o qtdAnos para qtdAnos:1, pois não tem casas decimais - eu postei errado lá em cima);
No texto do resultado, você utilizou "25 anos", mas de onde tirou este dado se ele ainda seria calculado pelo programa? utilize a variável correspondente!!!;
Você deixou as variáveis areaPetropolis e areaTeresopolis no programa, mas não está utilizando. Utilize-as;
Responda as perguntas em ordem e deixe os textos como se tivessem respondendo as questões numa prova. O resultado da densidade demográfica está incompleto.