Excel Localizar valor com 2 variavél

[LucasExcel]

Boa tarde

 

Preciso criar uma forma de ao inserir o nome e a data o excel localiza-se esse valor na planilha e iria colocar a seta em cima desse valor.

 

Segue em anexo a planilhaAvaliação.xlsx

Boa tarde, como são muitas datas, se possível so aparecer na caixa de seleção as datas ligadas ao nome selecionado.

 

Obs: Pode alterar  que for necessário para a fórmula

[Midori]

Em 23/04/2021 às 15:54, LucasExcel disse:

Preciso criar uma forma de ao inserir o nome e a data o excel localiza-se esse valor na planilha e iria colocar a seta em cima desse valor.

Que tipo de seta deve ser colocada?

 

E qual valor deve ser localizado? É na planilha dados? Nessa planilha tem várias colunas e diversos valores.

[LucasExcel]

@Midori Me expressei mal. Deixa eu tentar explicar novamente. Por favor ignorar a explicação do primeiro post.

 

Vamos la, 

O objetivo é poder, ao escolher um nome (célula E5)  e uma data  (célula L5) na aba "Historico"  que as informações (as duas linhas abaixo do nome, exemplo no anexo 1) na aba "dados" sejam copiados e colados na tabela da  aba  "Historico" na célula D18 em diante. Dessa forma ao colar os dados na aba "Historico" eu vou conseguir o gráfico dos dados (valores) antigos 

2Avaliação.xlsx

[CasaDoHardware]

Ja pensou em criar um grafico dinamico e duas segmentações de dados ai você consegue fazer isso sem o VBA e de foma dinamica.

 

Escolhe o nome e a data na segmentação e o grafico aparece conforme sua seleção.

 

[LucasExcel]

@CasaDoHardware não tinha pensado, mas fui tentar, o problema é que a linha em azul de F. C (BPM) muda os valores de acordo com cada pessoa, dessa forma eu não consigo por títulos. Ainda é possível criar um gráfico dinâmica?

Não consegui fazer

[Midori]

@LucasExcel Com Find e FindNext dá para encontrar a linha com as duas condições de nome e data assim,

Function ProcuraLinha(Nome As String, Data As Date) As Long
    Dim Celula      As Range
    Dim Linha       As Long
    Dim Encontrou   As Boolean
    
    Set Celula = Sheets("Dados").[A:A].Find( _
        What:=Nome, LookIn:=xlValues, LookAt:=xlWhole)
        
    If Not Celula Is Nothing Then
        Linha = Celula.Row
        Do
            If Celula.Offset(0, 1) = Data Then
                Linha = Celula.Row
                Encontrou = True
                Exit Do
            End If
            Set Celula = Sheets("Dados").[A:A].FindNext(Celula)
        Loop While Celula.Row > Linha
    End If
    If Encontrou = True Then ProcuraLinha = Linha
End Function

 

Teste a função no Change da planilha, o critério de nome está na célula E5 e data em L5,

If Not Intersect([E5,L5], Target) Is Nothing Then
    Dim Linha As Long
    Linha = ProcuraLinha([E5], [L5])
    If Linha <> 0 Then
        Sheets("Historico").[E18:AC19].ClearContents
        Sheets("Dados").Cells(Linha + 1, 1).Resize(2, 18).Copy
        Sheets("Historico").[D18].PasteSpecial xlPasteValues
        Application.CutCopyMode = False
    End If
End If

 

[LucasExcel]

@Midori Não entendi como eu utilizo o código. Da para colocar em um botão?

 

Não sei manusear código quando é função.

[Midori]

29 minutos atrás, LucasExcel disse:

Da para colocar em um botão?

Dá sim. Crie uma Sub para chamar a função e atualizar, pode ser assim,

 

Sub Atualizar()
    Dim Linha As Long
    Linha = ProcuraLinha([E5], [L5])
    If Linha <> 0 Then
        Sheets("Historico").[E18:AC19].ClearContents
        Sheets("Dados").Cells(Linha + 1, 1).Resize(2, 18).Copy
        Sheets("Historico").[D18].PasteSpecial xlPasteValues
        Application.CutCopyMode = False
    End If
End Sub

 

Aí é só atribuir essa macro ao botão.

 

[LucasExcel]

@Midori Muito obrigado, ficou perfeito