Excel Colocar Dados em Planilha salva em segundo plano

[diegojanjao]

Boa tarde.

 

Eu faço gestão de SAC em uma empresa e diariamente durante os chamados abertos, eu preciso criar uma pasta com o número do chamado, nome do cliente e nome do produto. 

Até aqui tudo bem pois eu consigo fazer com que ao colocar o código do produto, a planilha já cria a pasta no diretório e coloca o arquivo lá dentro que eu preciso.

 

O que eu gostaria era que, neste arquivo que é colocado lá dentro da pasta automaticamente, fosse incluído na célula G5 o número do chamado.

 

Private Sub Worksheet_change(ByVal Target As Range)
              
Dim raiz As Object, save
Set raiz = CreateObject("Scripting.FileSystemObject")

On Error Resume Next

             
       On Error GoTo aviso1
       
        If Target.Column = 7 And Target.Value <> "" Then 'PROCV DE CLIENTE
       
        Application.ScreenUpdating = False
        Cells(Target.Row, 5).Value = Date 'coloca data na coluna b
                            
        Cells(Target.Row, 8).Value = WorksheetFunction.VLookup(Cells(Target.Row, 7), Planilha4.Range("A2:I15000"), 3, False) 'Coloca CLIENTE
        Cells(Target.Row, 9).Value = WorksheetFunction.VLookup(Cells(Target.Row, 7), Planilha4.Range("A2:I15000"), 4, False) 'Coloca UF
        Cells(Target.Row, 71).Value = WorksheetFunction.VLookup(Cells(Target.Row, 7), Planilha4.Range("A2:I15000"), 5, False) 'Coloca DIVISÃO
                
        Application.ScreenUpdating = True
        
        End If
        
        If Target.Column = 10 And Target.Value <> "" Then 'PROCV DE PRODUTO
       
        Application.ScreenUpdating = False
                            
        Cells(Target.Row, 11).Value = WorksheetFunction.VLookup(Cells(Target.Row, 10), Planilha6.Range("A2:D15000"), 2, False) 'Coloca PRODUTO
        Cells(Target.Row, 14).Value = WorksheetFunction.VLookup(Cells(Target.Row, 10), Planilha6.Range("A2:D15000"), 3, False) 'Coloca FÁBRICA
        Cells(Target.Row, 69).Value = WorksheetFunction.VLookup(Cells(Target.Row, 10), Planilha6.Range("A2:D15000"), 4, False) 'Coloca LINHA
        save = ThisWorkbook.Path & "\" & Format(Cells(Target.Row, 4).Value, "000000") & " - " & Cells(Target.Row, 8).Value & " - " & Cells(Target.Row, 11).Value

        If Not raiz.FolderExists(save) Then
        raiz.CreateFolder (save)
        
        End If
        
        FileCopy ThisWorkbook.Path & "\FOR004 - Não conformidade.xlsx", _
        ThisWorkbook.Path & "\" & Format(Cells(Target.Row, 4).Value, "000000") & " - " & Cells(Target.Row, 8).Value & " - " & Cells(Target.Row, 11).Value & "\SAC " & Format(Cells(Target.Row, 4).Value, "000000") & " - Investig.xlsx"
                
        Application.ScreenUpdating = True
        
        End If
                        
        Exit Sub
aviso1:
MsgBox "Não foi possível localizar o item", vbOKOnly, "Recebimento CompreBem"


     
End Sub

 

Como eu faria para abrir o arquivo do FileCopy, colocar Format(Cells(Target.Row, 4).Value, "000000") na célula G5 deste arquivo e fechá-lo?

 

Obrigado.

FOR007 - Gestão do SAC - 2022rev4.zip

[Midori]

@diegojanjao Abra arquivo com Workbooks.Open, save e feche após editar a célula, p.ex,

 

Sub EditarPasta(Arquivo As String, Valor As String)
    Dim Pasta   As Workbook
    
    Set Pasta = Workbooks.Open(Arquivo)
        Pasta.ActiveSheet.[G5] = Valor
        Pasta.Save
        Pasta.Close
End Sub

 

Passe o caminho para o primeiro parâmetro e o valor formatado para o segundo.

[diegojanjao]

@Midori Muito obrigado. Funcionando certinho aqui.