Excel Erro na macro que agrupar vários arquivos excel em um só com várias abas.

[Luiz Filipe Porto]

Boa tarde. 

 

Fui usar a macro que o @Midoridesenvolveu para agrupar arquivos excel em um único com várias abas, mas estou me deparando com erros. 

 

Eis a macro (desenvolvida por @Midori) :

 

 

 

Agora, eis o erro que estou me deparando: 

 

 

 

 

 

Se possível, alguém poderia me ajudar? 

 

 

[Midori]

@Luiz Filipe Porto Essa linha procura a aba com o mesmo nome do arquivo. Você deve editar essa parte para o nome onde quer colar os dados.

[Luiz Filipe Porto]

@Midoriacompanhe comigo. 

 

Esse é o diretório onde estão as duas planilhas que estou usando como teste: 

 

 

Eis os dois arquivos abertos. Note que as abas possuem o mesmo nome do arquivos. 

 

 

 

Seguindo o que você falou, se é que entendi direito, inseri na linha em amarelo o nome do arquivo que desejo compilar todos os outros. 

 

O que não está correto?

[Midori]

@Luiz Filipe Porto Não é o nome do arquivo que deve ser especificado, mas da aba onde os dados devem ser colados. Se quiser colar tudo na mesma aba com o nome Tabela p.ex, o loop fica assim,

 

    Do Until Arquivo = ""
        Set Pasta = Workbooks.Open(Diretorio & Arquivo)
            Pasta.ActiveSheet.[A1].CurrentRegion.Copy
            
            With ThisWorkbook.Sheets("Tabela")
                Linha = .[A1].CurrentRegion.Rows.Count + 1
                .Cells(Linha, 1).PasteSpecial
            End With
            Pasta.Close
            Arquivo = Dir
    Loop

 

[Luiz Filipe Porto]

@MidoriEntão. No caso, usando o meu exemplo, eu gostaria de obter o seguinte resultado: 

 

Um novo arquivo excel, com nome "Output", que contém as planilhas 1 e 2 em abas diferentes. 

 

Como eu faria? 

 

[Midori]

@Luiz Filipe Porto Será mais fácil ajudar se você der mais detalhes do que quer fazer. Explicando como os dados estão nas planilhas do diretório Teste e como você quer que eles sejam importados para a planilha Output que é onde tem a macro.

[Luiz Filipe Porto]

@MidoriVamos lá. Suponhamos que, no diretório que mencionei no print, haja 10 arquivos diferentes .xlsx. Todos com nome "1", "2","3"..... "10" (nomes de exemplo apenas).  Eu quero juntar todos esses arquivos em um novo arquivo cujo nome é Output (nome de exemplo apenas), de forma que esse arquivo output contenha 10 abas (cada aba será um desses 10 arquivos diferentes que estão no diretório). A primeira delas se chama aba "1", a segunda "2", a terceira "3", até a décima "10". 

 

Vamos supor também que todas essas 10 planilhas estejam preenchidas da mesma forma: Célula A1 até Célula E49 preenchidas com dados (apenas um exemplo também. não necessariamente todas as 10 estariam preenchidas desde a célula A1 até a célula E49. Suponhamos que o arquivo "2" esteja preenchido apenas da célula A1 até A8.)

 

. 

 

[Midori]

@Luiz Filipe Porto A edição que deve ser feita como comentei antes é onde os dados deve ser colados. Assim a macro cria uma aba para cada arquivo. Veja se resolve,

 

Sub ImportaPlanilhas()
    Dim Arquivo     As String
    Dim Diretorio   As String
    Dim Pasta       As Workbook
    Dim Planilha    As Worksheet
    
    Diretorio = Environ("UserProfile") & "\Downloads\Teste\"
    Arquivo = Dir(Diretorio & "*.xlsx")
    
    Do Until Arquivo = ""
        Set Pasta = Workbooks.Open(Diretorio & Arquivo)
            Pasta.ActiveSheet.[A1].CurrentRegion.Copy
        Set Planilha = ThisWorkbook.Sheets.Add
            Planilha.Name = Replace(Pasta.Name, ".xlsx", "")
            Planilha.[A1].PasteSpecial
            Application.CutCopyMode = False
            Pasta.Close
            Arquivo = Dir
    Loop
End Sub

 

[Luiz Filipe Porto]

Perfeito, @Midori. Muito obrigado! 

 

Para terminar, vamos supor que eu deseje ordenar essas abas por data de modificacao do arquivo. 

 

Seria Possível?

[Midori]

@Luiz Filipe Porto Tem várias formas de fazer. A que acho mais simples é escolher um lugar na planilha para registrar a data da modificação, pode nas células das planilhas importadas ou então em outra aba para guardar só isso. Assim podemos aplicar algum algoritmo de ordenação para organizar as abas em ordem de modificação a partir da última data e hora. Para ordenar com base na célula X1 p.ex fica assim,

 

Sub ImportaPlanilhas()
    Dim Arquivo     As String
    Dim Diretorio   As String
    Dim Pasta       As Workbook
    Dim Planilha    As Worksheet
    
    Diretorio = Environ("UserProfile") & "\Downloads\Teste\"
    Arquivo = Dir(Diretorio & "*.xlsx")
    
    Do Until Arquivo = ""
        Set Pasta = Workbooks.Open(Diretorio & Arquivo)
            Pasta.ActiveSheet.[A1].CurrentRegion.Copy
        Set Planilha = ThisWorkbook.Sheets.Add
            Planilha.Name = Replace(Pasta.Name, ".xlsx", "")
            Planilha.[X1] = FileDateTime(Diretorio & Arquivo)
            Planilha.[A1].PasteSpecial
            Application.CutCopyMode = False
            Pasta.Close
            Arquivo = Dir
    Loop
    Call OrdenaPlanilha(ThisWorkbook)
End Sub

Sub OrdenaPlanilha(Pasta As Workbook)
    Dim I   As Integer
    Dim J   As Integer
    
    For I = 1 To Pasta.Sheets.Count - 1
        For J = 1 To Pasta.Sheets.Count - I - 1
            If Pasta.Sheets(J).[X1] < Pasta.Sheets(J + 1).[X1] Then
                Call Pasta.Sheets(J + 1).Move(Pasta.Sheets(J))
            End If
        Next J
    Next I
End Sub