Visual Basic Abrir pasta, percorrer todos os arquivos txt, somar valores.

[valbeezerra]

Salve, meus amigos

 

 Estou em busca de uma macro que: Abra a caixa de dialogo do Windows para que o usuário busque uma determinada pasta. Nela, contem varios arquivos na extensão txt.

 Conforme o print, todos os arquivos contem 7 linhas e seguem o mesmo padrão.

 O objetivo é percorrar todos os arquivos e contar quantas vezes surge o valor $50 e atribuir o total a uma variável.

 

 Grato a quem poder colaborar.

 

 

[ricardo_br]

Tem que ser em Visual Basic? A pasta muda com frequência? No exemplo que você postrou o resultado esperado seria 2 já que aparece 2x o número 50?

 

$50

$150

 

[valbeezerra]

@ricardo_br Obrigado por se dispor a ajudar.

 Sim, teria que ser em VB porque uso o excel. A pasta vem sempre nesse padrão, só muda a quantidade de arquivos. 

 Quanto ao texto a ser extráido, seria o que está após o "Buy-in:". que no caso, como pode obeservar,  tem um espaço antes do "$50".

[ricardo_br]

@valbeezerra Infelizmente só sei batch e um pouco de powershell, mais se quiser me mandar alguns desses arquivos em anexo para fazer alguns testes em batch....posso fazer um batch que mostra o total.....

[valbeezerra]

@ricardo_br

Exemplo.zip

[Midori]

@valbeezerra No VBA você pode selecionar a pasta com FileDialog e com Dir poderá listar os arquivos. Aí é só abrir no modo leitura para procurar o valor.

[valbeezerra]

@Midori Podia exemplicar na prática conforme o anexo que enviei ao Ricardo como ficaria? sou mega cru em vb. haha

[Midori]

@valbeezerra Veja se é isto.

 

A macro procura a linha de todos os arquivos txt que começa com Buy-in: para somar com o valor que vem após o cifrão. E o valor vai para a célula A1.

 

Sub SomaValor()
    Const LEITURA   As Integer = 1
    Dim Pasta       As Variant
    Dim Arquivo     As Object
    Dim Txt         As Object
    Dim Fso         As Object
    Dim StrLinha    As String
    Dim SpValor     As Variant
    Dim Soma        As Single
    
    Set Fso = CreateObject("Scripting.Filesystemobject")
    
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show = -1 Then
            Pasta = .SelectedItems(1)
            For Each Arquivo In Fso.GetFolder(Pasta).Files
                If LCase(Fso.GetExtensionName(Arquivo.Path)) = "txt" Then
                    Set Txt = Fso.OpenTextFile(Arquivo.Path, LEITURA)
                    Do Until Txt.AtEndOfStream
                        StrLinha = Txt.ReadLine
                        If Left(StrLinha, Len("Buy-in:")) = "Buy-in:" Then
                            SpValor = Split(StrLinha, "$")
                            If UBound(SpValor) = 1 Then
                                If IsNumeric(SpValor(1)) Then
                                    Soma = Soma + Trim(SpValor(1))
                                End If
                            End If
                        End If
                    Loop
                Txt.Close
                End If
            Next Arquivo
        End If
        [A1] = Soma
    End With
End Sub

 

[valbeezerra]

@Midori Isso ficou perfeito. Vou apenas fazer algumas adaptação. Fica aqui o meu agradecimento. Muito  obrigado!!

[ricardo_br]

Aqui está a versão batch, você copia o código abaixo para o bloco de notas, salva com o nome que quiser mais com extensão *.bat. Ai é só arrastar a pasta com os arquivos para o arquivo bat...

 

@echo off

if exist "%~1" (if not exist "%~1\" exit) else (exit)

for /f "delims=" %%a in ('dir /b "%~1\*.txt"') do for /f "tokens=2 delims=$" %%b in ('type "%~1\%%a"^|find /i "Buy-in:"') do call set /a Contador=%%Contador%%+%%b
echo.
echo Valor total: %Contador%
echo.
pause

 

[valbeezerra]

@ricardo_br Desculpe-me pela demora em responder. Só agora que fiz o procedimento.

 

 Quanto a funcionalidade, ache muito incrivel a rapidez com que percorre dodos os arquivos. Não sou programador, conheço muitissimo pouco vba e por isso achei que seria melhor para acrescentar algo e tal..

 

Duas perguntas perguntas: Assim, seria possível criar um gráfico em linha? Outra, seria possível ler o arquivo compactado?

 

No mais, fico grato por responder.

[ricardo_br]

@valbeezerra

Assim, seria possível criar um gráfico em linha?

 

 

Outra, seria possível ler o arquivo compactado? Sim mais antes tem que descompactar ele usando winrar, 7zip powershell ou outro.

 

[valbeezerra]

@Midori Essa macro que você partilhou, tem como adaptar de modo que leia até encotrar aprimeira linha vazia? o conteúdo que interessa está antes de duas linhas vazias. Derreti o cerebro e não achei como fazer isso hahaha. Pode me ajudar nisso?

[Midori]

@valbeezerra No loop da leitura das linhas coloque o critério para sair quando o tamanho for igual a zero,

 

Do Until Txt.AtEndOfStream
    StrLinha = Txt.ReadLine
                        
    If Len(StrLinha) = 0 Then
        Exit Do
    End If
...

 

[valbeezerra]

@Midori Show!! muito obrigado.