VisualG Ler 6 números e listar quais são pares e ímpares

[eulercruz_]

Crie um programa que leia 6 números inteiros e no final mostre quantos deles são pares e quantos são ímpares.

      

Apenas coloquei [] e {} para destacar os pares e ímpares, mas como faço o programa dizer quais são os pares e ímpares? Muito obrigado pela ajuda 

 

algoritmo "semnome"
var
   contador, N: inteiro
inicio
      contador <- 1
      Enquanto (contador <= 6) faca
               contador <- contador + 1
               Escreval ("Digite o número desejado: ")
               Leia (N)
               Se (N%2 = 0) então
                  Escreval ("[",N:1,"]")
               senao
                    Escreval ("{",N:1,"}")
               FimSe
      Fimenquanto
      
fimalgoritmo

fimalgoritmo

[Simon Viegas]

Dúvida:

47 minutos atrás, eulercruz_ disse:

Apenas coloquei [] e {} para destacar os pares e ímpares, mas como faço o programa dizer quais são os pares e ímpares? Muito obrigado pela ajuda 

 

O segredo para resolver qualquer problema é saber do que o problema se trata.

 

Enunciado:

45 minutos atrás, eulercruz_ disse:

Crie um programa que leia 6 números inteiros e no final mostre quantos deles são pares e quantos são ímpares.

 

Em qual momento estaria solicitando "quais"? Entende?

 

Imagine um cliente pedir um cachorro quente simples num restaurante, daí o garçom entrega um delicioso hambúrguer! "Oras! Meu consagrado, eu te pedi um cachorro quente. O que é isso?". 

 

A tua dúvida seria apenas um detalhe para finalizar o algoritmo... mais abaixo exemplifico como poderia ficar. Vou aproveitar para citar como sugeriria criar esboços:

 

- como são 6 números inteiros, ou seja, um quantidade fixa de leitura, ficaria mais simples utilizar para, em vez de enquanto.

- para simplificar os testes, utilizar uma quantidade menor, como apenas 2.

 

algoritmo "Quantidade de pares e ímpares"
//Crie um programa que leia 6 números inteiros e no final mostre quantos deles
//são pares e quantos são ímpares.

var
   i, numero : inteiro
inicio
   para i de 1 ate 2 faca //testando com 2, depois muda para 6
      leia(numero)
   fimPara

fimAlgoritmo

 

Daí só adicionar a verificação e exibir o resultado:

algoritmo "Quantidade de pares e ímpares"
//Crie um programa que leia 6 números inteiros e no final mostre quantos deles
//são pares e quantos são ímpares.

var
   i, numero : inteiro
   qtdPares, qtdImpares : inteiro
inicio
   qtdPares <- 0 //[1]
   qtdImpares <- 0

   para i de 1 ate 2 faca //testando com 2, depois muda para 6
      leia(numero)

      se (numero % 2 = 0) então
         qtdPares <- qtdPares+1
      senao //[2]
         qtdImpares <- qtdImpares+1
      fimSe
   fimPara

   escrevaL("Quantidade de pares   : ", qtdPares:1)
   escrevaL("Quantidade de ímpares : ", qtdImpares:1)
fimAlgoritmo

//1. como está funcionando como um contador, precisa* inicializar as variáveis
//   obs.: o VisualG já zera automaticamente, mas vai acostumando com a boa prática

//2. todo número inteiro OU é par, ou é ímpar. É uma dicotomia, logo, se não
//   for par, será necessariamente ímpar. Não precisa retestar

 

 

 

 

Sobre "dizer quais são os pares e ímpares", uma forma seria simplesmente exibir:

 

algoritmo "Quantidade de pares e ímpares"
//Crie um programa que leia 6 números inteiros e no final mostre quantos deles
//são pares e quantos são ímpares.

var
   i, numero : inteiro
   qtdPares, qtdImpares : inteiro
inicio
   qtdPares <- 0 //[1]
   qtdImpares <- 0

   para i de 1 ate 2 faca //testando com 2, depois muda para 6
      escrevaL("Digite o número desejado")
      leia(numero)

      se (numero % 2 = 0) então
         qtdPares <- qtdPares+1
         escrevaL("O número ", numero:1, " é par")
      senao //[2]
         qtdImpares <- qtdImpares+1
         escrevaL("O número ", numero:1, " é ímpar")
      fimSe

      escrevaL()
   fimPara
   escrevaL()
   escrevaL("Quantidade de pares   : ", qtdPares:1)
   escrevaL("Quantidade de ímpares : ", qtdImpares:1)
fimAlgoritmo

//1. como está funcionando como um contador, precisa* inicializar  as variáveis
//   obs.: o VisualG já zera automaticamente, mas vai acostumando

//2. todo número inteiro OU é para, ou é ÍMPAR. É uma dicotomia, logo, se não
//   for par, será necessariamente ímpar. Não precisa retestar

 

 

 

Após testar direitinho, muda para 6 números e testa.

 

Ah! para facilitar os testes, é possível gerar números aleatórios. Uma forma simples e rápida seria assim:

 

 

Para parar, só desativar novamente.

 

Aí vai ajustando até ficar da forma que desejar.

 

ADENDO: lembrando que o enunciado NÃO pede quais são pares ou ímpares, portando não devem ficar na versão final.

 

Um outro exemplo:

 

[eulercruz_]

@Simon Viegas Caramba, nem sabia dessa função para. Valeu dms.

Sempre via seus comentários nesse fórum e são os melhores sem dúvidas. Perdoe - me pelo erro de interpretação no começo. Tamo junto

[Simon Viegas]

Se estiver estudando enquanto... pode usar ele mesmo! Um outro princípio do dia a dia seria: se está estudando sobre um determinado tema, tecnicamente os exercícios são para serem aplicados com ele... mesmo que exista algo mais simples, por exemplo. Isso também parece óbvio depois que percebe.

 

Tipo... se rola um plano de estudos, quando "chegar no estudo do para", ficaria ainda mais claro porque o uso dele seria mais "adequado" para algumas situações (como desse exercício)... O para é para contextos mais específicos (basicamente que tem uma quantidade determinada de repetições), ao mesmo tempo, torna ele mais limitado (menos flexível em nível de condições de parada) que o enquanto ou repita. É análogo ao uso do escolha, que para situações mais específicas, pode substituir bem um conjunto de se/senão, mas fica limitado a poucos casos gerais.