Problema Formula Excel

fraldask8 · 16 de fevereiro de 2011

Boa tarde,

Estou com um problema serio em minha planilha onde, não sei mais qual formula utilizar:

Na tabela: "historico de itens", existe um campo chamado "Item", esse campo corresponde a qual item da linha B29:G29.

Sendo : 1 para B29

2 para c29

...

6 para g29

A pergunta e a seguinte: Ex: O nome "Bynox", apareceu na lista, e pegou um item numero 1, quero decrementar da pontuação final dele, o valor do item, para todos os itens que ele pegar.

1 = trinkt =decrementa 150;

2 = neck = decrementa 80;

No final gostaria de criar um campo, para mostrar quantos pontos ele ja gastou e quantos ele ainda possui....

Qualquer dúvida no meu raciocinio, pergunte...

http://www.4shared.com/document/D8k23ouM/Tabela_final_2_.html

zinhovba · 16 de fevereiro de 2011

Todas essas informações estão disponiveis no:http://www.4shared.com/file/91929774/85 ... IONAL.html, tenho certeza que vai te ajudar.

O que tem à fazer é baixa a planilha e ler esse texto que segue abaixo:

Se inserirem a listagem acima numa planilha a partir da célula A1, verão que o intervalo dos dados se estenderá até a linha 36 da coluna C.

Proponho em seguida algumas questões que responderemos em seguida utilizando a função SOMARPRODUTO.

1ª Questão: Qual o valor comprado pelos clientes no dia 04/mar?

2ª Questão: Qual o valor comprado entre os dias 01 e 03/mar?

3ª Questão: Qual o valor das compras realizadas pelo Pedro?

4ª Questão: Qual o valor das compras realizadas por Maria e Isabel

5ª Questão: Qual o valor das compras do Antônio nos dias 01/mar e 05/mar?

6ª Questão: Quantas compras foram realizadas por clientes com a inicial "J"?

Usaremos a seguinte sintaxe para a função: =SOMARPRODUTO((Argumento1)*(Argumento2)*(Argumento3)*...*(ArgumentoN)), onde cada argumento representa um intervalo de dados que pode, ou não, apresentar uma condição. A função trabalha, multiplicando o 1º elemento do 1º argumento, pelo 1º elemento do 2º argumento, e assim por diante até o 1º elemento do argumento N. Depois faz o mesmo com o 2º elemento, com o 3º e assim por diante, somando em seguida todos esses produtos.

1ª Questão

Antes da resposta é importante compreender como podemos informar ao Excel um valor de data, sendo que não podemos digitar 04/03/2009 diretamente em uma fórmula, pois seria interpretado como uma divisão de valores. As formas mais comuns, e igualmente eficazes, são:

a. Informar o número serial correspondente: 39876, que corresponde ao número de dias contados desde 01/01/1900 até a data corrente;

b. Utilizar a função DATA (=DATA(2009;3;4));

c. Utilizar a função Valor (=VALOR("04/03/2009").

d. Indicar uma célula que contenha o valor da data (por exemplo; $D$2)

Agora que sabemos com inserir uma data numa fórmula, vamos à condição propriamente dita. Queremos contabilizar todos os dias, presentes na coluna A, que sejam iguais a 04/mar. Desta forma nosso primeiro argumento será ($A$2:$A$36=VALOR("04/03/2009"))

Agora teremos que inserir o argumento que representa os valores a serem somados. No nosso caso ($C$2:$C$36). Temos então que a nossa fórmula fica assim=SOMARPRODUTO(($A$2:$A$36=VALOR("04/03/2009"))*($C$2:$C$36)), sendo o resultado igual a R$ 9.167.

2ª Questão:

Creio que podemos partir direto para a solução

=SOMARPRODUTO(($A$2:$A$36>=VALOR("01/03/2009"))*($A$2:$A$36<=VALOR("03/03/2009"))*($C$2:$C$36))

Onde :

Argumento1 representa todos os dias a partir de 01/03;

Argumento2 representa todos os dias anteriores a 03/03, incluindo também esta data.

O produto de Argumento1 * Argumento2, tem como resultante todos os dias compreendidos neste intervalo (matematicamente falamos que é a intersecção dos intervalos)

Finalmente Argumento3 representa os valores a serem somados com base nestas condições.

3ª Questão

=SOMARPRODUTO(($B$2:$B$36="Pedro")*($C$2:$C$36))

4ª Questão

=SOMARPRODUTO((($B$2:$B$36="Maria")+($B$2:$B$36="Isabel"))*($C$2:$C$36))

Vale a pena destacar o uso do sinal de adição para as condições, criando um argumento de uma forma diferente, cuja leitura pode ser "quero destacar todos os valores comprados por Maria somados os valores comprados por Isabel".

5ª Questão

=SOMARPRODUTO(($B$2:$B$36="Antônio")*(($A$2:$A$36=VALOR("01/03/2009"))+($A$2:$A$36=VALOR("05/03/2009")))*($C$2:$C$36))

Vale lembrar que não estamos falando do intervalo entre os dias e sim de cada data individualmente.

6ª Questão

=SOMARPRODUTO(1*(ESQUERDA($B$2:$B$36)="J"))

Este último é um exemplo de contagem e que só tem um argumento. Neste caso usamos o truque de multiplicar o argumento por 1.

Att...