VisualG Exercício de programação para responder

[Visitante]

ALGUÉM ME AJUDA POR FAVOR!

 

O ALGORITMO É ESSE:

 // Desenvolva um programa que efetue a leitura de 4 notas para 10 alunos,
// calcular a média e armazenar na 5ª coluna da matriz. Ao final imprimir
// a média final de cada aluno.

 

MEU CÓDIGO:

algoritmo "EXERCÍCIO 5"



var
 matriz: vetor [1..10, 1..5] de inteiro
 coluna, linha: inteiro
 media: real
inicio

 para linha <- 1 ate 10 faca
 para coluna <- 1 ate 4 faca

escreva ("DIGITE A NOTA", coluna," DO ALUNO", linha, ":")
leia (matriz [linha, coluna])

 fimpara
 escreval ()
 fimpara


// NÃO ESTOU CONSEGUINDO FAZER ESSA PARTE

media <- (linha + 1) / 4

 escreva ("a media é:", media)
 leia (matriz [0,5])

 escreva (matriz [linha, coluna, media])

 fimpara
 fimpara
fimalgoritmo

 

[Simon Viegas]

#1

Sempre mantenha seu código indentado. Para ajudar, no VisualG, pressione Ctrl+G.

 

 

#2

Sobre:

Em 23/01/2021 às 22:36, Larissa Ribeiro Tisutsura Dedi disse:

// NÃO ESTOU CONSEGUINDO FAZER ESSA PARTE

media <- (linha + 1) / 4

 escreva ("a media é:", media)
 leia (matriz [0,5])

 escreva (matriz [linha, coluna, media])

 fimpara
 fimpara

 

 

 

Então, o que é para ser feito?

 

Em 23/01/2021 às 22:36, Larissa Ribeiro Tisutsura Dedi disse:

[1] calcular a média

[2] armazenar na 5ª coluna da matriz.

[3] imprimi-la

 

Como se calcula uma média? Pesquise sobre o tema... entenda mais ou menos os tipos de médias que existem... mas vamos lá: provavelmente quer uma Média Aritmética Simples.

 

soma das notas / quantidade de notas

 

Onde estão as notas? Estão lá no vetor que você acabou de preencher...!

 

As notas do aluno, por exemplo, 3, estão em: matriz[3, 1], matriz[3, 2], matriz[3, 3], matriz[3, 4] e a sua média vai ficar em matriz[3, 5].

 

Só que você vai fazer isso para todos os alunos.

[Visitante]

Entendi. Só não sei como colocar a média na coluna 5 sem ter que escrever um por um. Por exemplo, se fosse 50 alunos daria muito trabalho. 

 

[Simon Viegas]

7 horas atrás, Larissa Ribeiro Tisutsura Dedi disse:

Entendi. Só não sei como colocar a média na coluna 5 sem ter que escrever um por um. Por exemplo, se fosse 50 alunos daria muito trabalho. 

 

Faça então apenas para um aluno e poste o código aqui.

 

 

[Simon Viegas]

Como já tem um tempinho, segue um exemplo de possível solução:

 

algoritmo "EXERCÍCIO 5"
var
   matriz: vetor [1..10, 1..5] de real
   coluna, linha: inteiro
   soma, media: real
inicio
   //leitura das notas
   para linha <- 1 ate 10 faca
      para coluna <- 1 ate 4 faca
         escreva ("DIGITE A NOTA ", coluna:1, " DO ALUNO ", linha:1, ": ")
         ALEATORIO 3, 10
         leia (matriz[linha, coluna])
         ALEATORIO off
      fimPara
      escreval()
   fimPara

   //calculo das médias
   para linha <- 1 ate 10 faca
      soma <- matriz[linha, 1] + matriz[linha, 2] + matriz[linha, 3] + matriz[linha, 4]
      media <- soma / 4
      matriz[linha, 5] <- media
   fimPara

   //impressão das médias
   para linha <- 1 ate 10 faca
      escreval("ALUNO ", linha:1, " MEDIA: ", matriz[linha, 5]:1:2)
   fimPara
fimAlgoritmo

 

 

 

Sugestão:

 

Utilize nomenclaturas de variáveis mais sugestíveis, exemplo:

var
   cardenetaNotas: vetor [1..10, 1..5] de real
   codAluno, codNota: inteiro
   somaNotas, mediaNotas: real

 

Pegue o código mais acima e altere as variáveis como no exemplo. Daí ajuste o código e poste aqui.