VisualG Como fazer Desdobramento VisualG

Vengefull · 6 de novembro de 2018

Boa noite, estou querendo criar um desdobramento aqueles com experiência no assunto poderia me ajudar ou melhorar esse código

eu quero inserir 36 números de 1 a 60 depois escolher dos 36 9 e ele fazer o desdobramento de 9 com as 36 números como faria isso e com um contador de máximo que pode chegar de combinação. obrigado desde já

Código:

Spoiler


Algoritmo "desdobramento"
Var
a,b,c,d,f,g,h,z,num_inseridos: inteiro
l,x,y,contador,num_escolhidos: inteiro
k,w,q,r,t,u                  : caractere
numeros_inseridos            : vetor[1..36] de inteiro
numeros_escolhidos           : vetor[1..36] de inteiro
procedimento insere_numeros
Inicio
  para a de 1 ate 36 faca
    numeros_inseridos[a] :=0
    numeros_escolhidos[a]:=0
  fimpara
  num_inseridos :=0
  num_escolhidos:=0
  escreval("          Vamos Inserir 36 Números Qualquer De 1 Até 60")
  para a de 1 ate 36 faca
    x:=1
    w:=numpcarac(a)
    se a<36 entao
      w:=" "+w
    fimse
    num_inseridos:=num_inseridos+1
    repita
      escreva("Digite o",w,"° Número Inteiro Maior Que 0 e Menor Que 60 (Ou Digite 60 Para Sair) ")
      leia(b)
      se (b>0) e (b<60) entao
        para c de 1 ate 36 faca
        se b=numeros_inseridos[c] entao
          escreval("Esse Número Já Foi Inserido,   Escolha Outro")
          x:=2
        fimse
        fimpara
        se x=1 entao
          numeros_inseridos[a]:=b
        fimse
      senao
        se b<>60 entao
          escreval("    Só Pode Ser Números De 1 Ate 60")
        fimse
        x:=2
      fimse
      se b=60 entao
        interrompa
      fimse
      x:=x-1
    ate x=0
    se b=60 entao
      num_inseridos:=num_inseridos-1
      interrompa
    fimse
  fimpara
  ord_crescente(36)
  escreval("     Aqui Estão Os",num_inseridos," Números Ineridos")
  escreva("    ")
  para a de 1 ate 36 faca
    se numeros_inseridos[a]<>0 entao
      escreva(numeros_inseridos[a]," ")
    fimse
  fimpara
  espera
fimprocedimento
procedimento Escolhe_numeros
inicio
  escreval(" Aqui Estão Os",num_inseridos," Números Inseridos        Aqui Estão Os 36 Números Escolhidos")
  para a de 1 ate 36 faca//mostrando os dez numeros
    k:=numpcarac(numeros_inseridos[a])
    w:=numpcarac(a)
    //q:=numeros_escolhidos[a]
    t:=numpcarac(numeros_escolhidos[a])
    q:=w
    se numeros_inseridos[a]<36 entao
      k:="  "+k
    fimse
    se (numeros_inseridos[a]>36) e (numeros_inseridos[a]<60) entao
      k:=" "+k
    fimse
    se a<36 entao
      w:=" "+w
    fimse
    //escreval(w,"° - Numero ",k)
    se a<9 entao
      escreval(w,"° - Numero ",k,"                                ",q,"° Número ",t)
    senao
      escreval(w,"° - Numero ",k)
    fimse
  fimpara
  escreval()
  escreval("Escolha 9 Números Para Fazer O Desdobramento E Algumas Combinações")
  se num_inseridos<9 entao
    escreval("Você Só Inseriu",num_inseridos," Números, "," Falta Inserir",10-num_inseridos," Números")
    escreval("entao Não Tem Como Você escolher Os 9 Números.  Saia E Insira Os 9 Números")
  fimse
  num_escolhidos:=0
  para a de 1 ate 9 faca//escolhendo 5 numeros
    x:=1
    y:=1
    num_escolhidos:=num_escolhidos+1
    repita
      escreva("Digite O",a,"° Número Dos Que Estão Na Lista Acima  (Ou Digite 1000 Para Sair) -> ")
      leia(b)
      para c de 1 ate 36 faca
        se numeros_inseridos[c]=b entao
          y:=2
        fimse
      fimpara
      se y=1 entao
        se b<>60 entao
          escreval("Esse Número Não Foi Inserido,   Escolha Outro")
        fimse
        x:=2
      senao
        para d de 1 ate 9 faca
          se numeros_escolhidos[d]=b entao
            escreval("     Esse Número Já Foi Escolhido,   Escolha Outro")
            x:=2
          fimse
        fimpara
        se (x=1) e (b<>60) entao
          numeros_escolhidos[a]:=b
        fimse
      fimse
      se b=60 entao
        num_escolhidos:=num_escolhidos-1
        interrompa
      fimse
      x:=x-1
    ate x=0
    se b=60 entao
      interrompa
    fimse
  fimpara
  escreval("     Pronto Foram Escolhidos",num_escolhidos," Números")
  ord_crescente2(9)
  escreva("             ")
  para a de 1 ate 9 faca
    escreva(numeros_escolhidos[a]," ")
  fimpara
  espera
fimprocedimento
procedimento faz_combinacoes
inicio
  contador:=0
  h:=35
  limpatela
  se num_inseridos<36 entao
    se num_inseridos=0 entao
      escreval("      Você Não Inseriu Nenhum Nùmero, Sendo Assim As Combinações")
      escreval("       Serão Feitas Usando Números Do Sistema, Que São Zeros")
    senao
      escreval("            Você Só Inseriu",num_inseridos," Números,  Sendo Assim As Combinações")
      escreval("   Serão Feita Usando Seus",num_inseridos," Números e Mais",10-num_inseridos," Números Do Sistema Que São Zeros")
    fimse
  fimse
  se num_escolhidos>0 entao
    escreva("   Esta é A Combinação Que Você Escolheu -> ")
    para a de 1 ate 9 faca
      se a<9 entao
        escreva(numeros_escolhidos[a],"- ")
      senao
        escreva(numeros_escolhidos[a])
      fimse
    fimpara
    escreval(" <-- Ela Estará Entre As Próximas Combinações")
  senao
    escreval()
  fimse
  para a de   1 ate 6 faca
    para b de a+1 ate 7 faca
      para c de b+1 ate 8 faca
        para d de c+1 ate 9 faca
          para f de d+1 ate 10 faca
            contador:=contador+1
            w:=numpcarac(numeros_inseridos[a])
            k:=numpcarac(numeros_inseridos[b])
            q:=numpcarac(numeros_inseridos[c])
            r:=numpcarac(numeros_inseridos[d])
            t:=numpcarac(numeros_inseridos[f])
            u:=numpcarac(contador)
            se contador<10 entao
              u:="00"+u
            fimse
            se (contador>9) e (contador<100) entao
              u:="0"+u
            fimse
            se numeros_inseridos[a]<36 entao
              w:="  "+w
            fimse
            se (numeros_inseridos[a]>9)e(numeros_inseridos[a]<100) entao
              w:=" "+w
            fimse
            se numeros_inseridos[b]<36 entao
              k:="  "+k
            fimse
            se (numeros_inseridos[b]>9)e(numeros_inseridos[b]<100) entao
              k:=" "+k
            fimse
            se numeros_inseridos[c]<36 entao
              q:="  "+q
            fimse
            se (numeros_inseridos[c]>9)e(numeros_inseridos[c]<100) entao
              q:=" "+q
            fimse
            se numeros_inseridos[d]<36 entao
              r:="  "+r
            fimse
            se (numeros_inseridos[d]>9)e(numeros_inseridos[d]<100) entao
              r:=" "+r
            fimse
            se numeros_inseridos[f]<36 entao
              t:="  "+t
            fimse
            se (numeros_inseridos[f]>9)e(numeros_inseridos[f]<100) entao
              t:=" "+t
            fimse
            x:=0
            z:=0
            para g de 1 ate 9 faca
              y:=numeros_escolhidos[g]
              se (y=caracpnum(w))ou(y=caracpnum(k))ou(y=caracpnum(q))ou(y=caracpnum(r))ou(y=caracpnum(t)) entao
                x:=x+1
              fimse
              se y=0 entao
                z:=z+1
              fimse
            fimpara
            escreva(u,"ª combinação --> ",w,"-",k,"-",q,"-",r,"-",t)
            se (x=9) e (z<>9) entao
              escreval("  <-- Aqui Está Aquela Combinação Que Você Escolheu")
            senao
              escreval()
            fimse
            se contador=h entao
              escreval("        Parado Para Vizualizar Essas Combinações")
              escreval("            Foram ",u," Combinações Até Aqui ")
              escreval("              Tecle Enter Para Continuar ")
              escreva("                             ")
              leia(g)
              limpatela
              h:=h+37
            fimse
          fimpara
        fimpara
      fimpara
    fimpara
  fimpara
  escreval("    Aí Estão Todas As Combinações De 9 Números Possíveis Com Esses 36 Números Inseridos")
  escreval("           Foram ",contador," Combinações")
  espera
fimprocedimento
procedimento espera
inicio
  escreval()
  escreval("         Tecle Enter Para Continuar ")
  escreva("                       ")
  leia(g)
fimprocedimento
procedimento ord_crescente(m:inteiro)
var
j,i,n : inteiro
inicio
  para j de 1 ate m-1 faca
    para i de j+1 ate m faca
      n:=numeros_inseridos[i]
      se numeros_inseridos[j]>n entao
         numeros_inseridos[i]:=numeros_inseridos[j]
         numeros_inseridos[j]:=n
      fimse
    fimpara
  fimpara
fimprocedimento
procedimento ord_crescente2(m:inteiro)
var
j,i,n : inteiro
inicio
  para j de 1 ate m-1 faca
    para i de j+1 ate m faca
      n:=numeros_escolhidos[i]
      se numeros_escolhidos[j]>n entao
         numeros_escolhidos[i]:=numeros_escolhidos[j]
         numeros_escolhidos[j]:=n
      fimse
    fimpara
  fimpara
fimprocedimento
procedimento mostra_inseridos
inicio
  limpatela
  escreval("    Aqui Estão Os ",num_inseridos," Números Inseridos")
  escreva("     ")
  para a de 1 ate 36 faca
    w:=numpcarac(numeros_inseridos[a])
    se (numeros_inseridos[a]>36)e (numeros_inseridos[a]<60) entao
      w:=" "+w
    fimse
    se numeros_inseridos[a]<36 entao
      w:="  "+w
    fimse
    se a<36 entao
      escreva(w," - ")
    senao
      escreva(w)
    fimse
  fimpara
  espera
fimprocedimento
procedimento mostra_escolhidos
inicio
  limpatela
  escreval("     Aqui Estão Os ",num_escolhidos," Números Escolhidos")
  escreva("        ")
  para a de 1 ate 36 faca
    w:=numpcarac(numeros_escolhidos[a])
    se (numeros_escolhidos[a]>36)e (numeros_escolhidos[a]<100) entao
      w:=" "+w
    fimse
    se numeros_escolhidos[a]<36 entao
      w:="  "+w
    fimse
    se a<5 entao
      escreva(w," - ")
    senao
      escreva(w)
    fimse
  fimpara
  espera
fimprocedimento
//******************************inicio*********************************
inicio
  repita
    limpatela
    escreval("          ***************************************")
    escreval("          *         Menu Principal              *")
    escreval("          *                                     *")
    escreval("          * 1 - Inserir  36 Números             *")
    escreval("          * 2 - Escolher  9 Números             *")
    escreval("          * 3 - Fazer Desdobramento             *")
    escreval("          * 4 - Mostrar Números Escolhidos      *")
    escreval("          * 5 - Mostrar Números  Inseridos      *")
    escreval("          * 6 - Para Terminar  O  Programa      *")
    escreval("          *                                     *")
    escreval("          ***************************************")
    escreval("                         _____")
    escreval("                        |     |")
    escreva("                        |  ")
    leia(l)
    escolha l
      caso 1
        insere_numeros
      caso 2
        Escolhe_numeros
      caso 3
        faz_combinacoes
      caso 4
        mostra_escolhidos
      caso 5
        mostra_inseridos
    fimescolha
  ate l=6
Fimalgoritmo

devair1010 · 6 de novembro de 2018

@Vengefull você quer inserir esses 36 números manualmente ou aleatório ?

Vengefull · 6 de novembro de 2018

eu queria os dois manualmente e aleatório para ver como se comporta obrigado pela resposta

Simon Viegas · 7 de novembro de 2018

Olá @Vengefull.

14 horas atrás, Vengefull disse:

Boa noite, estou querendo criar um desdobramento aqueles com experiência no assunto poderia me ajudar ou melhorar esse código

eu quero inserir 36 números de 1 a 60 depois escolher dos 36 9 e ele fazer o desdobramento de 9 com as 36 números como faria isso e com um contador de máximo que pode chegar de combinação. obrigado desde já

1#

Sugiro evitar esse tipo de escrita utilizando "Letras Maiúsculas No Início De Cada Palavra". Isso dificulta a leitura!

14 horas atrás, Vengefull disse:
escreval("          Vamos Inserir 36 Números Qualquer De 1 Até 60")

Veja a diferença:

escreval("         Vamos inserir 36 números qualquer de 1 até 60")

2#

Sobre:

14 horas atrás, Vengefull disse:


   para a de 1 ate 36 faca
      x:=1
      w:=numpcarac(a)
      se a<36 entao
         w:=" "+w
      fimse
      num_inseridos:=num_inseridos+1
      repita
         escreva("digite o",w,"° número inteiro maior que 0 e menor que 60 (ou digite 60 para sair) ")

Para quê está convertendo caractere? não entendi também esse se, ou seja, apenas para a última posição não vai dar espaço?

Em fim, por que não fazer assim?:

   para a de 1 ate 36 faca
      x:=1
      num_inseridos:=num_inseridos+1
      repita
         escreva("Digite o",a,"° número inteiro maior que 0 e menor que 60 (ou digite 60 para sair) ")

outra forma seria assim:

         escreva("Digite o ",a:1,"° número inteiro maior que 0 e menor que 60 (ou digite 60 para sair) ")

3#

Ainda sobre:

         escreva("Digite o ",a:1,"° número inteiro maior que 0 e menor que 60 (ou digite 60 para sair) ")

Como usuário (de programa), particularmente não acho interessante a "repetição de ordens" , ou seja, acho cansativo fica vendo "digite isso", "digite aquilo"... sugeriria orientar uma vez só ou até mesmo nem fazer.. apenas deixar implícito o que é para fazer.

No caso, deixei as "orientações" acima, veja:

   escreval("          Vamos inserir 36 números qualquer de 1 até 60")
   escreval()
   escreval("Insira os 36 números")
   escreval("obs.: números inteiros maiores que 0 e menores que 60")
   escreval()
   para a de 1 ate 36 faca
      x:=1
      num_inseridos:=num_inseridos+1
      repita
         escreva ("Número ",a:1,":")
         leia(b)
         se (b>0) e (b<60) entao
            para c de 1 ate 36 faca
               se b=numeros_inseridos[c] entao
                  escreval("Esse número já foi inserido, escolha outro")
                  x:=2
               fimse
            fimpara

4#

O Visuagl tem um recurso bem prático para "gerar dados aleatório". Veja um exemplo:

      repita
         ALEATORIO -10,80
         escreva ("Número ",a:1,":")
         leia(b)
         ALEATORIO OFF
         se (b>0) e (b<60) entao
            para c de 1 ate 36 faca

Basicamente seria que "todo leia() que estive entre o ALEATORIO, será preenchido automaticamente. Os número no lado é a faixa que resolvi deixar, ou seja, gerará aleatoriamente de -10 a 80.

***

Por enquanto é isso. Por favor, veja o que acha útil e implementa no código. Aí posta o novo código completo e onde especificamente gostaria de ajuda.

No aguardo.

devair1010 · 13 de novembro de 2018

@Vengefull seu código está com alguns erros , então modifique algumas linhas e ele ficou assim :

Algoritmo "desdobramento_3"
Var
  a,b,c,d,f,g,h,z,num_inseridos : inteiro
  aux,j,i,p,q,r,s,comb          : inteiro
  l,x,y,contador,num_escolhidos : inteiro
  num_inser_manual              : vetor[1..36] de inteiro
  numeros_escolhidos            : vetor[1..36] de inteiro
  numeros_aleatorios            : vetor[1..36] de inteiro

procedimento insere_numeros_manual
// oS comandoS ALEATORIO ON e  ALEATORIO OFF  escolhe os números automáticamente
// foi colocado aqui só para testar se o algoritmo está funcionando bem
// depois de testar remova esses dois comando para inserir manualmente
Inicio
  para a de 1 ate 36 faca
    num_inser_manual[a] := 0
    numeros_escolhidos[a]       := 0
  fimpara
  num_inseridos := 0
  num_escolhidos:= 0
  escreval("          Vamos inserir 36 números qualquer de 1 até 61")
  para a de 1 ate 36 faca
    num_inseridos := num_inseridos + 1
    repita
      x:=0
      escreva(a:1,"° número  (Ou Digite 999 para sair) ")
      aleatorio 1,60 // so para testar , depois remover essa linha
      leia(b)
      aleatorio off // so para testar , depois remover essa linha
      se ( b > 0 ) e ( b <= 60 ) entao
        para c de 1 ate 36 faca
        se b = num_inser_manual[c] entao
          escreval("Esse número já foi inserido,   escolha outro")
          x:=1
        fimse
        fimpara
        se x=0 entao
          num_inser_manual[a]:= b
        fimse
      senao
        se b<>60 entao
          escreval("    Só pode ser números de 1 ate 60")
        fimse
        x:=1
      fimse
      se b=999 entao
        interrompa
      fimse
    ate x=0
    se b=999 entao
      interrompa
    fimse
  fimpara

  para j de 1 ate 35 faca
    para i de j+1 ate 36 faca
      se num_inser_manual[j] >  num_inser_manual[i] entao
         aux                 := num_inser_manual[i]
         num_inser_manual[i] := num_inser_manual[j]
         num_inser_manual[j] := aux
      fimse
    fimpara
  fimpara

  escreval("     Aqui estão os 36 números ineridos")
  escreva("    ")
  para a de 1 ate 36 faca
    se num_inser_manual[a]<>0 entao
      escreva(num_inser_manual[a]:1," ")
    fimse
  fimpara
  espera
fimprocedimento

procedimento insere_numeros_aleatorio
inicio
  para j de 1 ate 36 faca
    numeros_aleatorios[j]:= 0
  fimpara
  para j de 1 ate 36 faca
    repita                     //repete   aleatorios
      x := 0                   //variável de controle
      b := randi(60) + 1       //escolhe aleatoriamente
      para c de 1 ate 36 faca  //loop repete 25 vezes *** mudar aqui ***
        se b = numeros_aleatorios[c] entao//se numero na posção da variável for igual
          x := 1               //x=1 para repetir
          interrompa
        fimse
      fimpara
    ate x = 0                   //ate que seja zero
    numeros_aleatorios[j] := b
  fimpara

  ord_crescente2(36)
  
  escreval
  escreval("         Aqui estão os 36 números inseridos aleatório")
  para j de 1 ate 36 faca
    se numeros_aleatorios[j] <> 0 entao
      escreva(numeros_aleatorios[j]:1," ")
    fimse
  fimpara
  
  espera
  
fimprocedimento

procedimento Escolhe_numeros
inicio
  escreval(" Aqui estão os 36 números inseridos")
  para a de 1 ate 36 faca
    escreval(a,"° - Numero ",num_inser_manual[a]:1)
  fimpara
  escreval
  escreva ("Escolha 9 números para fazer o desdobramento e")
  escreval(" Algumas Combinações")
  num_escolhidos:=0
  para a de 1 ate 9 faca//escolhendo 9 numeros
    y:=1
    num_escolhidos:=num_escolhidos+1
    repita
      x:=0
      escreva(a,"° número da lista acima  (Ou Digite 60 Para Sair) ")
      leia(b)
      para c de 1 ate 36 faca
        se num_inser_manual[c] = b entao
          y:=2
          interrompa
        fimse
      fimpara
      se y = 1 entao
        se b <> 60 entao
          escreval("Esse número não foi inserido,   escolha outro")
        fimse
        x := 1
      senao
        para d de 1 ate 9 faca
          se numeros_escolhidos[d] = b entao
            escreval("     Esse número já foi escolhido,   escolha outro")
            x:=1
            interrompa
          fimse
        fimpara
        se (x = 0) e (b <> 60) entao
          numeros_escolhidos[a]:= b
        fimse
      fimse
      se b = 60 entao
        interrompa
      fimse
    ate x = 0
    se b = 60 entao
      interrompa
    fimse
  fimpara
  escreval("     Pronto Foram Escolhidos 9 Números")
  ord_crescente2(9)
  escreva("             ")
  para a de 1 ate 9 faca
    escreva(numeros_escolhidos[a]:1," ")
  fimpara
  espera
fimprocedimento
procedimento faz_combinacoes
inicio
  contador := 0
  h := 42
  limpatela
  se num_inseridos<36 entao
    se num_inseridos=0 entao
      escreval("      Você não inseriu nenhum nùmero, nendo assim as combinações")
      escreval("       serão feitas usando números do sistema, que são zeros")
    senao
      escreval("            Você só inseriu",num_inseridos," números,  sendo assim as combinações")
      escreval("   serão feita usando seus",num_inseridos," números e mais",10-num_inseridos," números do sistema que são zeros")
    fimse
  fimse
  para a de   1 ate 9 faca
    para b de a+1 ate 9 faca
      para c de b+1 ate 9 faca
        para d de c+1 ate 9 faca
          para f de d+1 ate 9 faca
            para p de f+1 ate 9 faca
              para q de p+1 ate 9 faca
                para r de q+1 ate 9 faca
                  para s de  1 ate 36 faca
                    contador := contador + 1
                    se comb = 0 entao
                      escreva(contador:3,"ª combinação ---> ",numeros_escolhidos[a]:2)
                      escreva("-",numeros_escolhidos[b]:2,"-",numeros_escolhidos[c]:2)
                      escreva("-",numeros_escolhidos[d]:2,"-",numeros_escolhidos[f]:2)
                      escreva("-",numeros_escolhidos[p]:2,"-",numeros_escolhidos[q]:2)
                      escreva("-",numeros_escolhidos[r]:2,"-",num_inser_manual  [s]:2)
                    senao
                      escreva(contador:3,"ª combinação ---> ",numeros_aleatorios[a]:2)
                      escreva("-",numeros_aleatorios[b]:2,"-",numeros_aleatorios[c]:2)
                      escreva("-",numeros_aleatorios[d]:2,"-",numeros_aleatorios[f]:2)
                      escreva("-",numeros_aleatorios[p]:2,"-",numeros_aleatorios[q]:2)
                      escreva("-",numeros_aleatorios[r]:2,"-",num_inser_manual  [s]:2)
                    fimse
                    se contador = h - 20 entao
                      escreva("        Parado para vizualizar essas combinações")
                    senao
                      se contador = h - 19 entao
                        escreva("             foram ",contador+19:3," combinações até aqui ")
                      senao
                        se contador = h - 18 entao
                          escreva("              tecle enter para continuar ")
                        fimse
                      fimse
                    fimse
                    escreval
                    se contador = h entao
                      leia(g)
                      se g=9 entao
                        interrompa
                      fimse
                      limpatela
                      h := h + 42
                    fimse
                  fimpara
                fimpara
              fimpara
            fimpara
          fimpara
        fimpara
      fimpara
    fimpara
  fimpara
  escreval("    Aí estão todas as combinações de 9 números possíveis , com esses 36 números inseridos")
  escreval("           foram ",contador," combinações")
  espera
fimprocedimento

procedimento ord_crescente2(m:inteiro)
var
j,i,n,aux : inteiro
inicio
  para j de 1 ate m-1 faca
    para i de j+1 ate m faca
      se numeros_escolhidos[j] >  numeros_escolhidos[i] entao
         aux                   := numeros_escolhidos[i]
         numeros_escolhidos[i] := numeros_escolhidos[j]
         numeros_escolhidos[j] := aux
      fimse
    fimpara
  fimpara
fimprocedimento

procedimento espera
inicio
  escreval()
  escreval("         Tecle Enter Para Continuar ")
  escreva("                       ")
  leia(g)
fimprocedimento

procedimento mostra_inseridos
inicio
  limpatela
  escreval("    Aqui estão os ",num_inseridos," números inseridos")
  para a de 1 ate 36 faca
    escreva(num_inser_manual[a]:1)
    se a < 36 entao
      escreva(" - ")
    fimse
  fimpara
  espera
fimprocedimento

procedimento mostra_escolhidos
inicio
  limpatela
  escreval("numero 10",numeros_escolhidos[10])
  escreval("     Aqui estão os ",num_escolhidos," números escolhidos")
  para a de 1 ate 36 faca
    se numeros_escolhidos[a] <> 0 entao
      escreva(numeros_escolhidos[a]:1)
      se a < 36 entao
        escreva(" - ")
      fimse
    fimse
  fimpara
  espera
fimprocedimento

//******************************inicio*********************************

inicio
  repita
    limpatela
    escreval("          ***************************************")
    escreval("          *         Menu Principal              *")
    escreval("          *                                     *")
    escreval("          * 0 - Inserir  36 Números aleatorio   *")
    escreval("          * 1 - Inserir  36 Números manual      *")
    escreval("          * 2 - Escolher  9 Números             *")
    escreval("          * 3 - Fazer Desdobramento             *")
    escreval("          * 4 - Mostrar Números Escolhidos      *")
    escreval("          * 5 - Mostrar Números  Inseridos      *")
    escreval("          * 6 - Desdobramento com os aleatorios *")
    escreval("          * 7 - Para Terminar  O  Programa      *")
    escreval("          *                                     *")
    escreval("          ***************************************")
    escreval("                         _____")
    escreval("                        |     |")
    escreva ("                        |  ")
    leia(l)
    escolha l
      caso 0
        insere_numeros_aleatorio
      caso 1
        insere_numeros_manual
      caso 2
        Escolhe_numeros
      caso 3
        comb := 0
        faz_combinacoes
      caso 4
        mostra_escolhidos
      caso 5
        mostra_inseridos
      caso 6
         comb := 1
         faz_combinacoes
    fimescolha
  ate l=7
Fimalgoritmo