VisualG Média Aritmética Simples - Portugol

[LucasOne]

Nesse algoritmo, eu preciso que o algoritmo identifique os números positivos a serem inseridos pelo usuário e em seguida calcule a média entre eles. Eu consigo fazer a média de todos os números, mas não consigo fazer apenas as dos números positivos. Alguém me ajuda? Só posso usar SE, ESCOLHA e ENQUANTO até agora.

 

Algoritmo "Somador"
Var
   p, n,s , cont: Inteiro
   m: Real
Inicio
   EscrevaL ("Quantos numeros voce quer somar?")
   Leia (p)
   cont <- 1
   s <- 0
   m <- 0
   Enquanto (cont <= p) faca
      EscrevaL ("Por favor, digite o ", cont, "o valor: ")
      Leia (n)
      s <- s + n
      cont <- cont + 1
      m <- m + n
   FimEnquanto
   m <- m / p
   EscrevaL ("Soma: ", s)
   EscrevaL ("Media Aritmetica Simples: ", m)
FimAlgoritmo

 

[LuisOPsum]

Olá

É muito simples: você deve Informar como entrada, 2 Números "N1 e N2", ai você soma esses 2 números, e usar a formula pra calcular a média entre os 2 números.

Ex: (N1 + N2) / 7

Use o 'SE' para analisar, se o valor da média foi atingido pelo o aluno.

Na saída, você mostra o valor dessa média.

 

Espero ter ajudado.

[LucasOne]

20 minutos atrás, LuisOPsum disse:

Olá

É muito simples: você deve Informar como entrada, 2 Números "N1 e N2", ai você soma esses 2 números, e usar a formula pra calcular a média entre os 2 números.

Ex: (N1 + N2) / 7

Use o 'SE' para analisar, se o valor da média foi atingido pelo o aluno.

Na saída, você mostra o valor dessa média.

 

Espero ter ajudado.

 

Mas o problema não é esse...

[LuisOPsum]

Olá

Concordo no seu entendimento, mas a ideia similar foi apenas pra você ter mais clareza!

Eu fiz ter uma perspectiva do Roll.

programa
{
	inclua biblioteca Matematica --> mat

	funcao inicio()
	{
	   	real a, so, med = 0
		inteiro N, i 

		escreva("Digite a quantidade de numeros: ")
		leia(N)
        so = 0

	   para (i = 1; i <= N; i++)
	   {
		    escreva("Insira um número inteiros positivos: ")
		    leia(a)
			so = so + a
		}

		med = so / N
		
        escreva(" A media é: ", med)
	
	}
}

Espero ter ajudado.

[Simon Viegas]

Olá.

 

Vide definição do problema:

1 hora atrás, LucasOne disse:

Nesse algoritmo, eu preciso que o algoritmo identifique os números positivos a serem inseridos pelo usuário e em seguida calcule a média entre eles. Eu consigo fazer a média de todos os números, mas não consigo fazer apenas as dos números positivos. Alguém me ajuda? Só posso usar SE, ESCOLHA e ENQUANTO até agora.

 

 

Cerne da dúvida:

1 hora atrás, LucasOne disse:

mas não consigo fazer apenas as dos números positivos

 

Então, não consegue como? Qual a dúvida?

 

Vamos lá:

 

Primeiramente é preciso saber o que é um "número positivo". Quando que um número é positivo?... Será positivo quando ele for "maior que 0", certo? Só verificar isso e fazer as contas.

 

 

 

Segue um exemplo mais completo para referência:

 

algoritmo "Média dos números positivo"
var
   qtdNumeros: inteiro
   numero: real
   qtdPositivo: inteiro
   somaPositivo: real
   mediaPositivo: real
   cont: inteiro

inicio
   somaPositivo <- 0
   mediaPositivo <- 0

   escreval("Quantos números voce quer somar?")
   leia(qtdNumeros)

   cont <- 0
   enquanto (cont < qtdNumeros) faca
      cont <- cont + 1
      escreva ("Digite o ", cont:2, "º valor: ")
      ALEATORIO -20, 30
      leia(numero)
      ALEATORIO OFF

      se (numero >= 0) entao
         qtdPositivo <- qtdPositivo + 1
         somaPositivo <- somaPositivo + numero
      fimSe
   fimEnquanto

   se (qtdPositivo > 0) entao //evitar divisão por zero
      mediaPositivo <- somaPositivo / qtdPositivo
   fimSe

   escreval("")
   escreval("Quantidade de positivos: ", qtdPositivo:1)
   escreval("Soma dos positivos: ", somaPositivo:1:3)
   escreval("Media Aritmetica Simples dos positivos: ", mediaPositivo:1:3)
fimAlgoritmo

 

Perceba que a base é do teu código, apenas já sugerindo nomenclaturas de variáveis mais semânticas.

 

Qualquer dúvida é só reanalisar o código e tentar descobrir na internet (exercitar vestir a roupa de sapo)...

 

Se persistir com dúvidas ou sugestão é só postar também.