Excel Gerar gráficos no userform vba

[josequali]

Bom dia @LaerteB @Midori!

 

Atualmente criei uma planilha no Excel para poder carregar os gráficos da planilha do Excel no userform (são 4 gráficos). Procurei alguns tutoriais, mas só encontrei ensinando a carregar os gráficos em uma única imagem. Gostaria de carregar os gráficos automaticamente e separados em quatro quadros (imagem a 4), ao invés de ir clicando e ir passando de gráfico um por um. Sendo que todas vez que eu carregar o userform o gráfico já apareça automaticamente e atualizado, sem precisar da qualquer click. Segue em anexo o modelo que criei.

 

graficos.rar

[LaerteB]

Boa tarde, @josequali

 

Amigo é só você substituir este abaixo:

Private Sub NextButton_Click()
    If ChartNum = 4 Then ChartNum = 1 Else ChartNum = ChartNum + 1
    UpdateChart

End Sub

Por este que se segue:

Private Sub NextButton_Click()

  ChartNum = 1
    UpdateChart
    
  ChartNum = 2
    UpdateChart2
    
  ChartNum = 3
    UpdateChart3
    
  ChartNum = 4
    UpdateChart4
    
End Sub

 

E também acrescentar estes abaixo:

Private Sub UpdateChart2()
    Set CurrentChart = Sheets("Graficos").ChartObjects(ChartNum).Chart
    CurrentChart.Parent.Width = 350
    CurrentChart.Parent.Height = 250

    Fname = ThisWorkbook.Path & Application.PathSeparator & "temp.gif"
    CurrentChart.Export Filename:=Fname, FilterName:="GIF"

    Image2.Picture = LoadPicture(Fname)
End Sub
Private Sub UpdateChart3()
    Set CurrentChart = Sheets("Graficos").ChartObjects(ChartNum).Chart
    CurrentChart.Parent.Width = 350
    CurrentChart.Parent.Height = 250

    Fname = ThisWorkbook.Path & Application.PathSeparator & "temp.gif"
    CurrentChart.Export Filename:=Fname, FilterName:="GIF"

    Image3.Picture = LoadPicture(Fname)
End Sub
Private Sub UpdateChart4()
    Set CurrentChart = Sheets("Graficos").ChartObjects(ChartNum).Chart
    CurrentChart.Parent.Width = 350
    CurrentChart.Parent.Height = 250

    Fname = ThisWorkbook.Path & Application.PathSeparator & "temp.gif"
    CurrentChart.Export Filename:=Fname, FilterName:="GIF"

    Image4.Picture = LoadPicture(Fname)
End Sub

 

OBS: eu não tinha percebido bem a sua questão e pensei que queria somente a execução  para o botão "Gerar Gráficos",

mas tu queres que quando abrir o Userform já apareçam seus gráficos; então desta forma tu terás que colocar

este trecho do código no Initialize, conforme abaixo:

  ChartNum = 1
    UpdateChart
    
  ChartNum = 2
    UpdateChart2
    
  ChartNum = 3
    UpdateChart3
    
  ChartNum = 4
    UpdateChart4

 

Espero que seja isso que queria, por gentileza verifique e teste no seu projeto.

 

Aguardando sua resposta e seu Feed Back ... e não esqueça de clicar na "mãozinha" ,

pois com isso nos dá mais motivação para continuarmos ajudando ...

 

LaerteB

[Midori]

@josequali  Para carregar esses gráficos só precisa do Initialize, pode ser assim,

 

Private Sub UserForm_Initialize()
    Dim Grafico As ChartObject
    Dim Imagem  As Object
    Dim Arquivo As String
    Dim I       As Integer
    
    For Each Imagem In Me.Controls
        If TypeName(Imagem) = "Image" Then
            I = I + 1
            Set Grafico = Sheets("Graficos").ChartObjects(I)
                Arquivo = ThisWorkbook.Path & "\" & I & ".jpg"
                Grafico.Chart.Export Arquivo
                Imagem.Picture = LoadPicture(Arquivo)
        End If
    Next Imagem
End Sub

 

[josequali]

@Midori Perfeito! Obrigado!

[josequali]

@LaerteB obrigado!