Outro (PROMPT) Transformar data em semana

[Artilior]

Olá,

 

Eu utilizo a bat que ao iniciar o sistema, ele salva data e hora, porém queria saber se é possível transformar a data em semana para uma outra finalidade. E caso o computador seja ligado mais de uma vez na semana, o resultado seja subscrito.

 

 

Desde já agradeço.

[ricardo_br]

Como assim a data em semana você quer saber tipo o dia da semana seg, ter,qua,qui,sex,sab,dom ou tipo:

 

05/01/2021 = Semana 1 do ano...

21/01/2021 = Semana 4 do ano...

[Artilior]

Em 05/01/2021 às 16:04, ricardo_br disse:

05/01/2021 = Semana 1 do ano...

21/01/2021 = Semana 4 do ano...

 

Exatamente isso.

[ricardo_br]

Pode usar um for para pegar a Semana do Ano com a ajuda do powershell:

 

Um exemplo simples:

@echo off
for /f "tokens=1" %%a in ('powershell.exe get-date -UFormat %%V^') do set SemanaDoAno=%%a
echo %SemanaDoAno%
pause

 

Um exemplo um pouco mais complexo:

@echo off
SetLocal EnableDelayedExpansion
for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "BS=%%a"
Color 0E

:Inicio

IF NOT Defined Data set Data=%Date%
Call :PegaSemana
Title Semana do Ano
cls
echo.
echo  Data Atual %Date% - %Time:~0,5%
echo.
echo  Data: %Data% - %time:~0,5%
echo.
echo  Semana do Ano = !SemanaDoAno!
echo.
echo  Dia da Semana = !Dia!
echo.
set /p "Data=%BS% Para pesquisar outra data informe no seguinte formato: dd/mm/aaaa: "
call :PegaSemana
goto :Inicio
Exit

:PegaSemana
chcp 437> nul
for /f "tokens=1,2 delims=-" %%a in ('powershell.exe ^(get-date !Data! -UFormat %%V-%%A^)') do set SemanaDoAno=%%a&set Dia=%%b
chcp 1252> nul
goto :EOF

 

[Artilior]

Nossa, ficou muito bom e deu pra entender como funcionam os comandos. Muito obrigado.

Baseado nos exemplos, eu fiz umas alterações e também adicionei o comando pra pegar o dia da semana e jogar em um arquivo txt, porém o arquivo consta com uma sequencia dos dias da semana e não só uma vez.

 

[ricardo_br]

Poderia postar o código? Casa vez que você executa o batch ele adiciona uma linha e você queria que ele sobrescrevesse o resultado sempre é isso?

[Artilior]

@echo off
SetLocal EnableDelayedExpansion
for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "BS=%%a"
Color 0E

:Inicio

IF NOT Defined Data set Data=%Date%
Call :PegaSemana
echo !SemanaDoAno! > C:\Log\log_ligar.txt
Exit

:PegaSemana
chcp 437> nul
for /f "tokens=1,2 delims=-" %%a in ('powershell.exe ^(get-date !Data! -UFormat %%V-%%A^)') do set SemanaDoAno=%%a&set Dia=%%b
chcp 1252> nul
goto :EOF

 

Eu consegui resolver a questão de ficar repetindo em várias linhas e consegui que ele sobescreva, mas não consegui fazer o formato de duas casas decimais, ou seja, eu gostaria que o retorno dele no txt fosse no formato XX e não consegui também retirar esse espaço que fica depois do resultado.

[ricardo_br]

Tenta esse código:

 

@echo off
SetLocal EnableDelayedExpansion
for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "BS=%%a"
Color 0E

:Inicio

IF NOT Defined Data set Data=%Date%
Call :PegaSemana
> "C:\Log\log_ligar.txt" echo !SemanaDoAno!
Exit

:PegaSemana
chcp 437> nul
for /f "tokens=1,2 delims=-" %%a in ('powershell.exe ^(get-date !Data! -UFormat %%V-%%A^)') do set SemanaDoAno=%%a&set Dia=%%b
set SemanaDoAno=0!SemanaDoAno!
set SemanaDoAno=!SemanaDoAno:~-2!
chcp 1252> nul
goto :EOF

 

 

[Artilior]

Nossa, muito muito muito obrigado.

 

A explicação foi muito boa e deu pra entender tudo certinho.

 

Problemas resolvidos. 

[Artilior]

@ricardo_br Aconteceu um problema que hoje ele começou a marcar a semana como semana 05.

[ricardo_br]

Qual seria o erro?

[Artilior]

O intuito pra utilização desse batch é acompanhar a semana fiscal, o que nos coloca na semana 4 do mês, porém quando executo os comandos está atualizando para a semana 5

[ricardo_br]

Me desculpe a ignorância mais o que é uma "semana fiscal"?

Pelo que eu vi pelo batch ele sempre começa uma nova semana na quinta por alguma razão como pode ser visto na foto abaixo.

 

[ricardo_br]

No caso você queria que dia 1-7 fosse semana 1 | 8-14 semana 2  | 15-21 Semana 3...

Correto?

[Artilior]

 

Do dia 1 ao 3 não conta porque não fecha uma semana inteira, dai os setores financeiros e comerciais não levam em conta.

[ricardo_br]

Você quer usar os dados no excel? Já tentou a função NÚMSEMANA()?

[Artilior]

Na verdade eu preciso mesmo é do bloco de notas com esse número de semana para que um outro programa de uma máquina Laser o leia e imprima o número na peça.
O que eu faço é usar o agendamento do computador pra rodar o batch todos os dias, mas agora eu parei pra pensar e a melhor solução mesmo seria rodá-lo apenas uma vez na semana pra que isso não ocorra.

[ricardo_br]

Ok, vou tentar fazer um aqui essa semana que rode começando a contagem na primeira segunda-feira do ano.

[Artilior]

Então, descobri qual é o real problema.

Eu vou precisar de uma condicional pra verificar se é segunda, terça ou quarta feira e se sim, que ele rode o script.
Como esse ano a semana começou em uma sexta feira, o computador entende que quinta é o ultimo dia da semana e atrapalha tudo, então o ideal seria essa condicional. Com isso fica tudo perfeito