VisualG Algoritmo que leia valores inteiros e encontre o maior e o menor deles

[rafaznj]

Escreva um algoritmo que leia valores inteiros e encontre o maior e o menor deles.

Termine a leitura se o usuário digitar zero (0);

 

Fiz algum progresso na construção, mas ainda sim há erros no algoritmo. Não sei como fazer com que o antigo número maior seja comparado com o número digitado

 

Var:
   num, maior, menor, comp1, comp2 : inteiro

Inicio:
   repita
      escreval ("digite o numero: ")
      leia (num)
      se(num > maior) então
         comp1 := maior
         maior:= num
      senao
         comp2 := num
      fimse
      se (comp1 < comp2) então
         menor := comp1
      senao
         menor := comp2
      fimse

   ate (num = 5)
   escreval ("", maior)
   escreval ("", menor)

 

[devair1010]

@rafa amateur    a condução de saída do programa é quando digitar zero , e você colocou 5 para terminar , e creio que só precisa mesmo é de três variáveis ,  e mais uma para controlar a inicialização no início  ,  e usando o Botão code "<>" ,  seu código ficou assim  :

Algoritmo "maior e menor_211"
Var
  num , maior, menor  : inteiro
  comp1 , comp2 , flg : inteiro
Inicio
  repita
    escreval ("digite o numero: ")
    leia (num)
    se flg = 0 então  // não pode ter til 
      maior := num
      menor := num
        flg := 1
    fimse
    se num <> 0 então // o corretor ortografico do forum
      se(num > maior) então // inseriu errado
        maior := num
      senao
        se menor > num então
          menor := num
        fimse
      fimse
    senao
      escreval( "Maior -> ", maior)
      escreval( "Menor -> ", menor)
    fimse
  ate num = 0
fimalgoritmo

 

[rafaznj]

@devair1010 Obrigado Devair. Não entendi ao certo o que seria a variável "flg" ?

[devair1010]

@rafa amateur    essa flg serve para pegar o primeiro valor inserido e armazenar nas variáveis "maior" e "menor"  pois a variável menor foi criada e preenchida com valor zero lá antes do início e então para que ela  modificasse esse valor só poderia ser um número negativo , e alí ao guardar o primeiro valor nessas variáveis , a flg é modificada e assim não permite pegar outro valor , e assim essa parte do programa não interfere nas comparações seguintes .

[Simon Viegas]

Um outro exemplo:

 

algoritmo "maior e menor"
var
   num, maior, menor : inteiro
   primeiro : logico
inicio
   primeiro <- VERDADEIRO

   repita
      escreva ("Digite o numero: ")
      leia(num)

      se num <> 0 então
         se primeiro então
            maior <- num
            menor <- num
            primeiro <- FALSO
         senao
            se(num > maior) então
               maior <- num
            senao
               se menor > num então
                  menor <- num
               fimSe
            fimSe
         fimSe
      fimSe
   ate num = 0

   se maior <> 0 então
      escrevaL( "Maior -> ", maior:1)
      escrevaL( "Menor -> ", menor:1)
   senao
      escrevaL("Nenhum valor diferente de 0 foi informado")
   fimSe
fimalgoritmo