Excel Macro para excluir coluna, transpor e numerar

[Diegodcr]

Bom dia senhores(as)

Estou com várias planilhas num diretório c:\planilhas que necessitam de uma macro pra excluir as linhas 1, 2 e 3 e coluna A. Depois inserir nova guia e colar com a opção transpor a nova linha 1. Na colagem a linha 1 irá virar coluna A na nova guia e tera de forma aleatória o nome transpor que deverá na coluna B e linha abaixo da palavra transpor, começar contar até a última linha da coluna A.

planilha base2.xls planilha correta.xls planilha base1.xls

[Midori]

Edit.

Agora vi que transpor aparece na coluna D da correta, mas nas bases não.

[Diegodcr]

@Midori Ela vai aparecer na plan1 e sempre será na linha 2 porém da coluna B, C, D, E, F... Isso após excluir a linha 1, 2 e 3.

[Midori]

@Diegodcr Faça um teste, se transpor aparecer na última coluna não terá numeração. Para pegar todas as planilhas faça um loop no diretório passando os nomes como argumento para o procedimento.

 

Sub MacroTransporValores()
    Call TransporValores(Workbooks.Open("C:\planilhas\planilha base1.xls"))
End Sub

Sub TransporValores(Planilha As Workbook)
    Dim Aba     As Worksheet
    Dim Nova    As Worksheet
    Dim Area    As Range
    Dim Linha   As Long
    Dim Conta   As Long
    
    Set Aba = Planilha.ActiveSheet
    
    Aba.[A:A].EntireColumn.Delete
    Aba.[1:3].EntireRow.Delete
    
    Set Nova = Planilha.Worksheets.Add
    
    Call Aba.[1:1].Copy
    Call Nova.[A1].PasteSpecial(Transpose:=True)
    
    If WorksheetFunction.CountIf(Nova.[A:A], "transpor") Then
        Linha = WorksheetFunction.Match("transpor", Nova.[A:A], 0)
        Conta = Nova.[A1].CurrentRegion.Rows.Count
        If Conta - Linha > 0 Then
            Set Area = Nova.Cells(Linha + 1, "B").Resize(Conta - Linha)
            Area.Formula = "=ROW()-" & Area.Cells(1).Row - 1
            Area.Value = Area.Value
        End If
    End If
End Sub

 

[Diegodcr]

@Midori Consegue porém não consegui deixar que a nova aba (planilha1) fique como segunda aba. Ela ta ficando como primeira aba.

[Midori]

@Diegodcr No parâmetro After de Add passe a primeira planilha,

 

Set Nova = Planilha.Worksheets.Add(After:=Planilha.Sheets(1))