Servidor de Arquivos quantidade de arquivos salvos por extenssões.

[eriston coelho]

Existe algum relatorio emitido pelo servidor de arquivo do WINDOWS SERVER , que mostre a quantidade de arquivos salvos por extenssões.

[ricardo_br]

@eriston coelho Se não existe você pode fazer um script que faça isso.

[eriston coelho]

Poderia me mostrar um script ja feito?

[ricardo_br]

 

Usando um arquivo .bat:

@echo off
chcp 1252 > nul
setlocal EnableDelayedExpansion

:: QExtTot = Quantidade de extensões totais existentes
:: NExt[n] = Nome da extensão
:: QExt[n] = Quantidade de cada extensão

set "Resultado=%~dp0resultado.txt"
set "ATemp=%temp%\VExtencao\Lista01.txt"

:Inicio
If "%~1"=="" (set /p "Pasta=Informe a Pasta: ") else (set "Pasta=%1")

IF /i Not Exist "%Pasta%" goto :Inicio

for %%a in ("%Pasta%") do set "Pasta=%%~dpnxa"
pushd "%Pasta%"

IF /i exist "%ATemp%" Del /q /f /a "%ATemp%"
IF /i  not Exist "%temp%\VExtencao" md "%temp%\VExtencao"
:: for /f "Delims=" %%a in ('(for /f "Delims^=" %%b in ('dir /b /s /a-d') do @echo %%~xb^|%%~fb)') |sort	

for /f "delims=" %%a in ('dir /b /s /a:-d /o:e') do echo %%~xa^|%%~fa>>"%ATemp%"


for /f "tokens=1,2 Delims=|" %%a in ('type "%ATemp%" ^|sort') do call :VerificaExtencao "%%~a"

pause

echo Pasta Pai: %Pasta%: >>"%Resultado%"
echo.>>"%Resultado%"
for /L %%a in (1,1,%QExtTot%) do (
                                  echo !NExt[%%a]:~1! = !QExt[%%a]!: >>"%Resultado%"
                                  echo.>>"%Resultado%"
                                  for /f "delims=" %%b in ('dir /s /b /a *!NExt[%%a]!') do echo %%~nxb  -^>	%%~fb>>"%Resultado%"
                                  echo.>>"%Resultado%"
                                 
                                 )

exit
:VerificaExtencao
IF /i not "%Extencao%"=="%~x1" (
                                Set /a QExtTot+=1
                                Set NExt[!QExtTot!]=%~x1
                                set "Extencao=%~x1"
                                set /a QExt[!QExtTot!]+=1                                
                               ) else (
                                       set /a QExt[!QExtTot!]+=1
                                      )
goto :EOF