Dúvida como fazer Algoritmo no visualG

[Ronaldo José]

Leia um número real e um inteiro e faça a exponenciação (sem utilizar exp() ou ^).

[legolas3d]

Caro amigo, não implemente o algoritimo no visualg, eu fiz ele em C usando o devC++, porém fiz alguns comentarios para ajudar o seu entendimento.

#include<stdlib.h>//biblioteca da linguagem C

#include<stdio.h>//biblioteca da linguagem C

#include<math.h>//biblioteca da linguagem C

int main()//equivalente a inicio no portugues estruturado

{

float numero, resultado;//declaração de variavel real

int expoente;//declaração de variavel inteira

printf("Insira um numero: ");//equivalente a escrever no portugues estruturado

scanf("%f", &numero);//equivalente a ler no portugues estruturado

printf("\nInsira um expoente: ");//equivalente a escrever no portugues estruturado

scanf("%d",&expoente);//equivalente a ler no portugues estruturado

resultado=pow(numero,expoente);//função pow da biblioteca math.h que faz exponenciação.

printf("Resultado: %f", resultado);//imprime o resultado na tela

printf("\n");//comando \n serve para quebrar a linha

system("pause");

return 0;

}//equivalente a fim no portugues estruturado

Desculpe por não ter feito como você queria, mais espero que tenha dado alguma luz para você.

Se não ajudei me desculpe.

[Visitante]

Fiquei curioso com a solução do legolas3d, pena que ainda não entendo de Linguagem C.

Mesmo assim apresento uma solução alternativa.

Neste algoritmo utilizei as variáveis:

X - Base;

Y - Expoente;

P - Potência;

N - Variável auxiliar para o laço 'para';

var

    Y, N: inteiro
    X, P: real 

A seguir o código para calcular a potência de um número real sem ter que utilizar a expressão P <- X ^ Y.

Não se esqueça que a base X é um número real (positivo ou negativo) e o expoente Y é um número inteiro (positivo ou negativo).

escolha Y de
    caso 0
        P <- 1
    caso 1
        P <- X
    caso -1
        P <- 1 / X
    outrocaso
        P <- X
        para N de 2 ate abs (Y) faca
            P <- P * X
        fimpara
        se Y < 0 então
            P <- 1 / P
        fimse
fimescolha

Este outro algoritmo é um exemplo completo, basta copiar e colar no Visualg, ele está pronto para executar.

Ele possui mais duas variáveis:

Opcao - Oferece uma escolha: parar ('s' e Enter) ou continuar (outra letra e Enter) a execução do programa;

ContinuaExecucao - Não permite parar a execução do programa até que se digite 's' e Enter quando solicitado.

algoritmo "Potenciacao"

var

    ContinuaExecucao: logico
    Y, N: inteiro
    X, P: real
    Opcao: caractere

inicio

    ContinuaExecucao <- verdadeiro
    enquanto ContinuaExecucao faca
        limpatela
        escreva ("Base: ")
        leia(X)
        escreva ("Expoente: ")
        leia(Y)
        escreval
        escolha Y de
            caso 0
                P <- 1
            caso 1
                P <- X
            caso -1
                P <- 1 / X
            outrocaso
                P <- X
                para N de 2 ate abs (Y) faca
                    P <- P * X
                fimpara
                se Y < 0 então
                    P <- 1 / P
                fimse
        fimescolha
        escreval ("Potencia: ", P)
        escreval
        escreva ("Tecle s e Enter para sair ou outra letra e Enter para continuar: ")
        leia (Opcao)
        se Opcao = "s" então
            ContinuaExecucao <- falso
        fimse
    fimenquanto

fimalgoritmo

Espero ter te ajudado.

[JhOnE RoSsInI]

use o portugol 2.3 mais fácil vou colocar ele no rapidshare pra você com tutorial video aula só pra você ter uma noção dai você passa pro visualg beleza

link pra baixar portugol 2.3

http://search.4shared.com/q/1/portugol%202.3