Bat Login e senha em .bat seguido de Menu

[AVSS]

Preciso fazer script em .bat.

Fazer login e senha para depois de aceito,  ser "ligado" a um Menu. Alguém poderia me ajudar? 

[ricardo_br]

Digamos que o usuário seria "Ricardo" e a senha "123"

 

@echo off

chcp 1252 > nul
set Usuario=Ricardo
set Senha=123

:Inicio
cls
set Opcao1=
set Opcao2=
echo.
echo  Favor informe Usuário e Senha para acessar o menu:
echo.
Set /p "Opcao1=Usuário: "
set /p "Opcao2=Senha: "

IF /i not "%Opcao1%"=="%Usuario%" goto :SenhaInvalida 
IF not "%Opcao2%"=="%Senha%" goto :SenhaInvalida

:Menu
cls
echo.
echo  Bem vindo ao menu
echo.
echo  [1] Opção 1
echo.
echo  [2] Opção 2
echo.
echo  [3] Opção 3
echo.
echo  [4] Sair
echo.
set /p "Opcao=Escolha uma opção: "

exit



:SenhaInvalida
cls
echo.
echo  Usuário ou Senha Inválidas!
echo.
pause
goto :Inicio

 

Salve o arquivo bat como ANSI para  que os acentos funcionem:

 

 

 

 

[AVSS]

Quais seria o script para que a máquina reinicie, hiberne, desligue? Poderia me ajudar? 

[ricardo_br]

@AVSS

8 minutos atrás, AVSS disse:

Quais seria o script para que a máquina reinicie, hiberne, desligue? Poderia me ajudar? 

 

Hibernar:

C:\Windows\System32\rundll32.exe powrprof.dll,SetSuspendState 0,1,0

 

Bloquear computador:

%windir%\system32\rundll32.exe user32.dll,LockWorkStation

 

Desligar:

shutdown /s /t 0

 

Reiniciar:

shutdown /r /t 0

 

[AVSS]

Por gentileza, Como ficaria o script pra esse? Poderia ajudar?

[ricardo_br]

Basicamente você detecta cada opção do usuário com um IF e depois usa um goto para encaminhar para o submenu que o usuário escolheu...

 

echo  -------------------------------
echo    Bem vindo ao Menu Principal
echo  -------------------------------
echo.
echo  [P]ACOTE LIBRE OFFICE
echo.
echo  [S]ERVICOS DE REDE
echo.
echo  [A]PLICATIVOS Windows
echo.
echo  [G]ERENCIAMENTO DA MAQUINA
echo.
echo  [E]NCERRAR sessão
echo.
echo  [F]INALIZAR PROGRAMA
echo.
set /p "Opcao=%BS% Escolha uma opção: "

IF /i "%Opcao%"=="P" goto :MenuOffice
IF /i "%Opcao%"=="S" goto :MenuRede
IF /i "%Opcao%"=="A" goto :MenuApps
IF /i "%Opcao%"=="G" goto :MenuGerenciamento
IF /i "%Opcao%"=="E" goto :Inicio
IF /i "%Opcao%"=="F" goto :Fim 
goto :MenuPrincipal

 

[ricardo_br]

Aqui tem um exemplo de como o batch poderia ser:

 

 

@echo off
mode con: cols=90 Lines=25 1> nul 2> nul
chcp 1252 > nul
setLocal EnableDelayedExpansion
color 0e

set Usuario=Ricardo
set Senha=123

for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "BS=%%a"
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do set "DEL=%%a"

:Inicio
cls
set Opcao1=
set Opcao2=
set Opcao=
echo.
echo  Favor informe Usuário e Senha para acessar o menu:
echo.
Set /p "Opcao1=%BS% Usuário: "
set /p "Opcao2=%BS% Senha: "

IF /i not "%Opcao1%"=="%Usuario%" goto :SenhaInvalida 
IF not "%Opcao2%"=="%Senha%" goto :SenhaInvalida

:MenuPrincipal
cls
echo.
echo  -------------------------------
echo    Bem vindo ao Menu Principal
echo  -------------------------------
echo.
echo  [P]  PACOTE MICROSOFT OFFICE
echo.
echo  [PL] PACOTE LIBRE OFFICE
echo.
echo  [S]ERVICOS DE REDE
echo.
echo  [A]PLICATIVOS Windows
echo.
echo  [G]ERENCIAMENTO DA MAQUINA
echo.
echo  [E]NCERRAR sessão
echo.
echo  [F]INALIZAR PROGRAMA
echo.
set /p "Opcao=%BS% Escolha uma opção: "

IF /i "%Opcao%"=="P" goto :MenuOffice
IF /i "%Opcao%"=="PL" goto:MenuLOffice
IF /i "%Opcao%"=="S" goto :MenuRede
IF /i "%Opcao%"=="A" goto :MenuApps
IF /i "%Opcao%"=="G" goto :MenuGerenciamento
IF /i "%Opcao%"=="E" goto :Inicio
IF /i "%Opcao%"=="F" goto :Fim 
goto :MenuPrincipal

:Fim
exit



:SenhaInvalida
cls
echo.
echo  Usuário ou Senha Inválidas!
echo.
pause
goto :Inicio

:MenuOffice
set Opcao=
cls
echo.
echo  -------------------------------
echo      PACOTE MICROSOFT OFFICE
echo  -------------------------------
echo.
echo  [W]ORD
echo  [E]XCEL
echo  [A]CCESS
echo  [P]OWER POINT
echo  [R]ETORNAR AO MENU PRINCIPAL
echo.
set /p "Opcao=%BS% Escolha uma Opção: "

IF /i "%Opcao%"=="W" start WINWORD.EXE
IF /i "%Opcao%"=="E" start EXCEL.EXE
IF /i "%Opcao%"=="A" start MSACCESS.EXE
IF /i "%Opcao%"=="P" start POWERPNT.EXE
if /I "%Opcao%"=="R" goto :MenuPrincipal
goto :MenuOffice

:MenuLOffice
set Opcao=
cls
echo.
echo  ------------------------------
echo        PACOTE LIBRE OFFICE
echo  ------------------------------
echo.
echo  [W]riter
echo  [C]alc
echo  [B]ase
echo  [I]mpress
echo  [R]ETORNAR AO MENU PRINCIPAL
echo.
set /p "Opcao=%BS% Escolha uma Opção: "

IF /i "%Opcao%"=="W" start swriter.exe
IF /i "%Opcao%"=="C" start scalc.exe
IF /i "%Opcao%"=="B" start sbase.exe
IF /i "%Opcao%"=="I" start simpress.exe
if /I "%Opcao%"=="R" goto :MenuPrincipal
goto :MenuLOffice



:MenuRede
cls
echo.
echo  -----------------------------------
echo          SERVICOS DE REDE
echo  -----------------------------------
echo.
echo  [N]AVEGAR INTERNET
echo  [T]ESTAR CONEXAO DE REDE
echo  [O]BTER O IP DA MAQUINA
echo  [R]ETORNAR AO MENU PRINCIPAL
echo.
set /p "Opcao=%BS% Escolha uma opção: "

IF /i "%Opcao%"=="N" start www.google.com
IF /i "%Opcao%"=="T" goto :TestarConexao
IF /i "%Opcao%"=="O" goto :ObterIP
If /i "%Opcao%"=="R" goto :MenuPrincipal
goto :MenuRede 


:MenuApps
cls
echo.
echo  ----------------------------------
echo        APLICATIVOS DO Windows
echo  ----------------------------------
echo.
echo  [C]ALCULADORA
echo  [T]ECLADO VIRTUAL
echo  [W]INDOWS EXPLORER
echo  [P]AINT
echo  [B]LOCO DE NOTAS
echo  [R]ETORNAR AO MENU PRINCIPAL
echo.
set /p "Opcao=%BS% Escolha uma opção: "

IF /i "%Opcao%"=="C" start calc
IF /i "%Opcao%"=="T" start osk
IF /i "%Opcao%"=="W" start Explorer
IF /i "%Opcao%"=="P" start mspaint
IF /i "%Opcao%"=="B" start notepad
if /I "%Opcao%"=="R" goto :MenuPrincipal
goto :MenuApps


:MenuGerenciamento
cls
echo.
echo  ----------------------------------
echo       GERENCIAMENTO DE MAQUINA
echo  ----------------------------------
echo.
echo  [DM] DESLIGAR A MAQUINA
echo  [RM] REINICIAR A MAQUINA
echo  [HM] HIBERNAR A MAQUINA
echo  [R] RETORNAR MENU PRINCIPAL
echo.
set /p "Opcao=%BS% Escolha uma Opção: "

IF /i "%Opcao%"=="DM" shutdown /s /t 0
IF /i "%Opcao%"=="RM" shutdown /r /t 0
IF /i "%Opcao%"=="HM" C:\Windows\System32\rundll32.exe powrprof.dll,SetSuspendState 0,1,0
IF /I "%Opcao%"=="R" goto :MenuPrincipal
goto :MenuGerenciamento

:TestarConexao
set Contador=0
set CI=
set CL=
set Segunda=
set Teste=
cls
echo.
echo  ----------------------------
echo     TESTAR CONEXAO DE REDE
echo  ---------------------------- 
echo.
:TesteInternet
ping -n 1 -4 -w 1000 www.google.com 1> nul 2> nul
IF "%errorlevel%"=="0" (set CI=OK&set CorCI=0A) else (set CI=FALHA&set CorCI=0C)
set /a Contador+=1
If /i not "%CI%"=="OK" If %Contador% LEQ 3 goto :TesteInternet

for /f "delims=[] tokens=2" %%a in ('ping -4 -n 1 %computername%') do set IP=%%a
for /f "tokens=2,3 delims={}," %%a in ('wmic nicconfig get defaultIPGateway^,ipaddress /format:csv ^|Find /i "%IP%"') do for /f "delims=" %%c in ("%%~b") do set Teste=%%c

If not defined Teste (
                      set CL=FALHA
                      set CorCL=0C
                     ) else (
                             set CL=OK
                             set CorCL=0A
                            )

call :ColorText 0e " Conexao da Internet   ["
call :ColorText %CorCI% "%CI%"
call :ColorText 0e "]"
echo.
call :ColorText 0e " Conexao da Rede Local ["
call :ColorText %CorCL% "%CL%"
call :ColorText 0e "]"
echo.
echo.
pause
goto :MenuRede

:ObterIP
set IPPublico=
set IP=
cls
echo.
echo  ----------------------------------------
echo           Obter IP do Computador
echo  ----------------------------------------
echo.
echo.
for /f "delims=[] tokens=2" %%a in ('ping -4 -n 1 %computername%') do set IP=%%a
for /f "tokens=2 skip=3" %%a in ('"nslookup myip.opendns.com resolver3.opendns.com 2>Nul"') do for /f "Delims=" %%b in ("%%a") do set IPPublico=%%b

Call :ColorText 0E " IP Local"
Call :ColorText 0A "       %IP%"
echo.
Call :ColorText 0E " IP Publico"
Call :ColorText 0A "     %IPPublico%"
echo.
echo.
pause
goto :MenuRede

:ColorText
echo off
<nul set /p ".=%DEL%" > "%~2"
findstr /v /a:%1 /R "^$" "%~2" nul
del "%~2" > nul 2>&1
goto :eof