VisualG Pesquisar se o número existe na matriz dá erro

[Irwing Seiji Ato]

Algoritmo "semnome"
// Disciplina  :  [Linguagem e Lógica de Programação]
// Professor   : Antonio Carlos Nicolodi
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Nome do(a) aluno(a)
// Data atual  : 16/05/2019
Var
   // Seção de Declarações das variáveis
   matris:vetor[1..5,1..5] de real
   i,j:inteiro
   numero:real
Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         escreval("Digite um número na posição [",i,"]","[",j,"]")
         leia(matris[i,j])
      fimpara
   fimpara
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         escreva("[",i,"]","[",j,"] = ",matris[i,j]," ")
      fimpara
      escreval("")
   fimpara
   escreval("Digite um número para ser pesquisado na matriz:")
   leia(numero)
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         se(numero = matris[i][j])
            escreval("O número digitado existe na posição: [",i,"]","[",j,"]")
         fimse
      fimpara
   fimpara
Fimalgoritmo

Este é o código porém dá erro ao pesquisar se o número existe na matriz dá esse erro

[devair1010]

@Irwing Seiji Ato    é só dois colchetes hum abre outro fecha ,  e o  i  e o   j  separado por vírgula , e não precisa abre  parenteses e fecha parenteses .

[Simon Viegas]

Em 16/05/2019 às 16:04, Irwing Seiji Ato disse:

se(numero = matris[i][j])

 

Além do comentado por @devair1010, faltou também o entao.

 

Ficaria algo assim:

se (numero = matris[i,j]) entao

obs.: o () é facultativo, mas não tem problema deixar.

 

 

Como é só um ajuste na condicional, segue abaixo código com outras sugestões:

algoritmo "semnome"
// Disciplina  :  [Linguagem e Lógica de Programação]
// Professor   : Antonio Carlos Nicolodi
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Irwing Seiji Ato
// Data atual  : 16/05/2019
var
   matris :vetor[1..5,1..5] de real
   i,j :inteiro
   numero :real
inicio
   ALEATORIO 1, 30
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         escreval("Digite um número na posição [",i:1,"]","[",j:1,"]")
         leia(matris[i,j])
      fimPara
   fimPara
   ALEATORIO OFF
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         escreva("[",i:1,"]","[",j:1,"] = ",matris[i,j]:2," ")
      fimPara
      escreval("")
   fimPara
   escreval("Digite um número para ser pesquisado na matriz:")
   leia(numero)
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         //se(numero = matris[i][j])
         se (numero = matris[i,j]) entao
            escreval("O número digitado existe na posição: [",i:1,"]","[",j:1,"]")
         fimse
      fimPara
   fimPara
fimAlgoritmo

 

 

Ou assim:

algoritmo "semnome"
// Disciplina  :  [Linguagem e Lógica de Programação]
// Professor   : Antonio Carlos Nicolodi
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Irwing Seiji Ato
// Data atual  : 16/05/2019
var
   matris :vetor[1..5,1..5] de real
   i,j :inteiro
   numero :real
inicio
   ALEATORIO 1, 30
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         escreval("Digite um número na posição [",i:1,",",j:1,"]")
         leia(matris[i,j])
      fimPara
   fimPara
   ALEATORIO OFF
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         escreva("[",i:1,",",j:1,"] = ",matris[i,j]:2," ")
      fimPara
      escreval("")
   fimPara
   escreval("Digite um número para ser pesquisado na matriz:")
   leia(numero)
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
         se (numero = matris[i,j]) entao
            escreval("O número digitado existe na posição: [",i:1,",",j:1,"]")
         fimse
      fimPara
   fimPara
fimAlgoritmo