Outro Arquivo BAT, para verificar a existência de um usuário

[Jason GBDS]

Bom dia, precisava de ajuda para criar um batch, que realize o seguinte procedimento porém não consegui encontrar a solução.

Problema: Verifique e o usuário existe, se ele existir ele atualiza a senha. Caso contrario ele cria um novo usuário.

O código de criação de usuário eu conheço, mas esse de verificar se existe eu já não sei. Se alguém souber solucionar esse problema ficaria muito grato! Obrigado desde já!

[ricardo_br]

Com atualizar a senha você quer dizer trocar a senha atual por outra?

 

O arquivo bat tem que perguntar ao usuário o nome do usuário ou já é um usuário especifico?

[Jason GBDS]

@ricardo_br

1 hora atrás, ricardo_br disse:

Com atualizar a senha você quer dizer trocar a senha atual por outra?

 

O arquivo bat tem que perguntar ao usuário o nome do usuário ou já é um usuário especifico?

 Seria atualizar a senha por outra, mas tudo já pré definido.

Exemplo: Senha Atual do usuário "Hardware" 123 --> Mudar para 1234, sempre que o comando for executado e esse usuário existir ele atualizará a senha. Caso contrário cria um Usuário Hardware com senha 1234.

 

[ricardo_br]

Poderia ser algo assim, no caso o bat precisa ser executado como administrador. Se alem de criar a conta Hardware você também quer que essa conta seja uma conta Administradora é só adicionar:

 

"net localgroup Administradores %Usuario% /add" logo abaixo de "net user %Usuario% %Senha% /add"

 

@echo off
chcp 1250 1> Nul 2> Nul
net session 1> Nul 2> Nul

If %Errorlevel% EQU 2 (
echo.
Echo O bat precisa ser executado como Administrador
echo.
pause
exit
)

set Usuario=Hardware
set Senha=1234
echo.
net user %Usuario% 1> Nul 2> Nul

If %errorlevel% EQU 0 (
echo O usuário: %Usuario% existe, a senha será atualizada agora.
timeout /t 5
net user %Usuario% %Senha%
)

if %errorlevel% EQU 2 (
echo O usuário: %Usuario% não existe, ele será criado agora.
timeout /t 5
net user %Usuario% %Senha% /add
)

pause

 

 

[Jason GBDS]

@ricardo_br

Em 04/12/2019 às 16:13, ricardo_br disse:

Poderia ser algo assim, no caso o bat precisa ser executado como administrador. Se alem de criar a conta Hardware você também quer que essa conta seja uma conta Administradora é só adicionar:

 

"net localgroup Administradores %Usuario% /add" logo abaixo de "net user %Usuario% %Senha% /add"

 

@echo off
chcp 1250 1> Nul 2> Nul
net session 1> Nul 2> Nul

If %Errorlevel% EQU 2 (
echo.
Echo O bat precisa ser executado como Administrador
echo.
pause
exit
)

set Usuario=Hardware
set Senha=1234
echo.
net user %Usuario% 1> Nul 2> Nul

If %errorlevel% EQU 0 (
echo O usuário: %Usuario% existe, a senha será atualizada agora.
timeout /t 5
net user %Usuario% %Senha%
)

if %errorlevel% EQU 2 (
echo O usuário: %Usuario% não existe, ele será criado agora.
timeout /t 5
net user %Usuario% %Senha% /add
)

pause

 

 

 

Sensacional! Era isso mesmo que precisava!! Perfeito! Obrigado!

Teria como me explicar o  comando "chcp 1250 1> nul  2>null" e "net session 1> Nul 2> Nul"

[ricardo_br]

chcp 1250 1> nul 2> nul: Troca a página de codificação para 1250 permitindo caracteres com acentos tipo "é" "ê" "á" a parte de nul envia tipo qualquer mensagem resultante do comando para um "buraco negro" para que não seja exibido nada na tela. Por padrão depois de usar chcp seria exibido algo assim na tela: "Página de código ativa: 1250" mais como usei nul foi tipo enviado para o nada.

 

net session 1> Nul 2> Nul: Net session é um comando para gerenciar sessões de compartilhamento. No caso eu apenas o usei para detectar se o prompt de comando está sendo usado como Administrador, sendo que o comando precisa ser executado como administrador se ele for executado em um prompt de comando normal gera um código de erro 2 ai sempre que gera esse código 2 mostra uma mensagem para o usuário e em seguida encerra o bat.

 

 

[Jason GBDS]

@ricardo_br

Aproveitando sua ajuda, e mudando um pouco do assunto tema, mas ainda sim sobre batch.

Tem a possibilidade de eu colocar o ip da maquina em uma variável?

[ricardo_br]

Esse salva o IP versão 4 em IPv4 e IP versão 6 em IPv6:

 

@echo off
chcp 1252 1> Nul 2> Nul
Rem Isso pega o IP versão 4:
for /f "delims=[] tokens=2" %%a in ('ping -4 -n 1 %computername%') do set IPv4=%%a
Rem Isso pega o IP versão 6:
for /f "delims=[] tokens=2" %%a in ('ping -6 -n 1 %computername%') do set IPv6=%%a
echo.
echo Seu IPv4 é: %IPv4%
echo Seu IPv6 é: %IPv6%
echo.
pause

[Jason GBDS]

@ricardo_br  Show de boa! Isso mesmo.. valeu

 

[Jason GBDS]

Em 09/12/2019 às 12:45, ricardo_br disse:

Esse salva o IP versão 4 em IPv4 e IP versão 6 em IPv6:

 

 

@echo off
chcp 1252 1> Nul 2> Nul
Rem Isso pega o IP versão 4:
for /f "delims=[] tokens=2" %%a in ('ping -4 -n 1 %computername%') do set IPv4=%%a
Rem Isso pega o IP versão 6:
for /f "delims=[] tokens=2" %%a in ('ping -6 -n 1 %computername%') do set IPv6=%%a
echo.
echo Seu IPv4 é: %IPv4%
echo Seu IPv6 é: %IPv6%
echo.
pause

 

 Me veio uma duvida, de como pegar o restante do endereço do computador, Mascara, Gateway.. Tem como?

 

[ricardo_br]

Eu adicionei mais algumas coisas mais vou colocar como anexo para que o tópico não fique muito comprido.

IP.zip