VisualG Matrizes com critérios de valores e junção de matrizes

[Soul1Gamer]

ALGUÉM PODERIA ME AJUDAR NESSE EXERCÍCIO DE CÓDIGO VISUALG?

 

Ler duas matrizes A e B de uma dimensão com 12 elementos. A matriz A deverá aceitar
apenas a entrada de valores que sejam divisíveis por 2 ou 3, enquanto a matriz B deverá
aceitar apenas a entrada de valores que não sejam múltiplos de 5. A entrada das matrizes
deverá ser validada pelo programa e não pelo usuário. Construir uma matriz C de forma que
a matriz C seja a junção das matrizes A e B, e de forma que a matriz C contenha 24
elementos. Apresentar a matriz C.

[Simon Viegas]

Caro usuário,

 

Seja bem-vindo ao Clube do Hardware.

 

No intuito de servir como fonte de pesquisa no caso de instituições de ensino, informamos que incorrer no resolvimento por completo de questões relacionadas a disciplinas escolares de cursos técnicos e faculdades podem ser revistas e removidas pela Equipe de Moderação do Clube do Hardware.

 

Para sanar dúvidas sobre esse tipo de problema, por gentileza, publique o passo a passo do desenvolvimento da questão, projeto, monografia ou conteúdo em dúvida para que possamos analisar se a resposta está correta ou não, ou para que possa ser auxiliado com a dúvida no desenvolvimento do exercício.

 

Infelizmente, não há como resolver os trabalhos pelos usuários. O objetivo do Clube do Hardware é auxiliar seus usuários a encontrar soluções para que possam sanar suas dúvidas, e não de trazer soluções prontas para seus usuários. Além disso, copiar e colar respostas que não são de autoria própria do qualquer usuário é considerado plágio, o que é ilegal.

 

Esperamos que compreenda.

 

Atenciosamente,

Equipe Clube do Hardware

[devair1010]

@Soul1Gamer @Soul1Gamer   para criar vetores e matrizes no visualG , você coloca o nome seguido de dois pontos e a quantidade de elementos e em seguida o tipo que nesse caso é inteiro ,  depois para inserir os números nesse vetor você usa o comando leia , e para que aceite apenas divisíveis por 2 e 3 , use o comando  se  , que fará essa verificação , e poste seu código aqui , assim poderemos ajudar    .

[Soul1Gamer]

@Simon Viegas peço desculpa, eu não sabia que não podia...

 

adicionado 18 minutos depois

@devair1010

algoritmo "semnome"
// função :
// autor :
// data : 16/06/2020
// seção de declarações
var
   a: vetor [1..12] de inteiro
   b: vetor [1..12] de inteiro
   c: vetor [1..24] de inteiro
   i: inteiro
inicio
   para i de 1 ate 12 passo 1 faca
      escreva ("digite o",i,"° valor: ")
      leia (a[i])
      se (a[i] mod 2=0) ou (a[i] mod 3=0) entao
         c[i] <- a[i]
      fimse
   fimpara
   para i de 1 ate 12 passo 1 faca
      escreva ("digite o",i,"° valor: ")
      leia (b[i])
      se (b[i] <> 5) entao
         c[i+12] <- b[i]
      fimse
   fimpara
   para i de 1 ate 24 passo 1 faca
      escreval ("os valores lidos de ",i,"° são:",c[i])
   fimpara
   // seção de comandos
fimalgoritmo

 

[Simon Viegas]

@Soul1Gamer, o enunciado se refere a múltiplos:

 

15 horas atrás, Soul1Gamer disse:

enquanto a matriz B deverá aceitar apenas a entrada de valores que não sejam múltiplos de 5

 

Mas você está comparando com um valor fixo:

41 minutos atrás, Soul1Gamer disse:

se (b[i] <> 5) entao

 

Só corrigir.

 

adicionado 9 minutos depois

Ah! os vetores não estão sendo preenchidos corretamente... 

 

O vetor A deve ser todo preenchido com os valores válidos... Idem para B. E por fim C será será apenas a junção... ou seja: como a lógica para A e B não estão corretas, C vai dar problema também.

 

[devair1010]

@Soul1Gamer    seu código está funcionando bem faltou fazer a validação , então dentro se coloque uma variável que informa se o que foi digitado está dentro do esperado ou não e caso não esteja então repita esse mesmo comando leia sem que a variável i seja incrementada , e para isso você pode usar o comando repita / ate , e seu código com algumas modificações poderia ser assim  :

algoritmo "matriz unidimensional"
// data : 16/06/2020
var
  a: vetor [1..12] de inteiro
  b: vetor [1..12] de inteiro
  c: vetor [1..24] de inteiro
  i: inteiro
  certo : logico
inicio
  para i de 1 ate 12 passo 1 faca
    repita
      certo <- falso
      escreva ("digite o",i,"° valor: ")
      leia (a[i])
      se (a[i] mod 2 = 0) ou (a[i] mod 3 = 0) entao
        c[i] <- a[i]
        certo <- verdadeiro
      fimse
    ate certo
  fimpara
  escreval
  para i de 1 ate 12 passo 1 faca
    repita
      certo <- falso
      escreva ("digite o",i,"° valor: ")
      leia (b[i])
      se (b[i] mod 5 <> 0) entao
        c[i+12] <- b[i]
        certo <- verdadeiro
      fimse
    ate certo
  fimpara
  escreval
  escreval("os valores lidos da Matriz c :")
  para i de 1 ate 24 passo 1 faca
    escreval(i:2,"° é :",c[i]:3)
  fimpara
fimalgoritmo