Portugol Como fazer laços com portugol?

[Big_Big]

Construa um algoritmo que leia o sexo e a cor dos cabelos de várias pessoas, conforme a figura 1. Enquanto a resposta para a pergunta “Quer continuar?” for S, o algoritmo deve continuar lendo o sexo e a cor dos cabelos, somente após a resposta ser N é que o laço de repetição deve ser interrompido.

<

Na imagem mostra como tem que ficar, se possível, preciso da resposta até 18 horas de amanhã 25/06/2021

[Matheus Dutra]

57 minutos atrás, Big_Big disse:

Construa um algoritmo que leia o sexo e a cor dos cabelos de várias pessoas, conforme a figura 1. Enquanto a resposta para a pergunta “Quer continuar?” for S, o algoritmo deve continuar lendo o sexo e a cor dos cabelos, somente após a resposta ser N é que o laço de repetição deve ser interrompido.

<

Na imagem mostra como tem que ficar, se possível, preciso da resposta até 18 horas de amanhã 25/06/2021

Olá @Big_Big, estamos aqui para te ajudar a resolver o problema, não dar ele pronto. Então se tiver alguma coisa especifica que esteja com dúvida, ou algum código que voce já tentou fazer, e querer postar ele aqui, ai sim poderia te ajudar. Se ganhar esse exercício pronto, sem ter feito nada, voce não vai conseguir fazer nenhum próximo exercício, logo vai precisar da resposta para todos. 

[DiF]

Caro usuário,

 

Seja bem-vindo ao Clube do Hardware.

 

No intuito de servir como fonte de pesquisa no caso de instituições de ensino, informamos que incorrer no resolvimento por completo de questões relacionadas a disciplinas escolares de cursos técnicos e faculdades podem ser revistas e removidas pela Equipe de Moderação do Clube do Hardware.

 

Para sanar dúvidas sobre esse tipo de problema, por gentileza, publique o passo a passo do desenvolvimento da questão, projeto, monografia ou conteúdo em dúvida para que possamos analisar se a resposta está correta ou não, ou para que possa ser auxiliado com a dúvida no desenvolvimento do exercício.

 

Infelizmente, não há como resolver os trabalhos pelos usuários. O objetivo do Clube do Hardware é auxiliar seus usuários a encontrar soluções para que possam sanar suas dúvidas, e não de trazer soluções prontas para seus usuários. Além disso, copiar e colar respostas que não são de autoria própria do qualquer usuário é considerado plágio, o que é ilegal.

 

Esperamos que compreenda.

 

Atenciosamente,

Equipe Clube do Hardware

[Big_Big]

Algoritmo "Pesquisa"

var

pesquisa, sim, não, sexo, sexoFeminino, sexoMasculino : caractere
corCabelo, cabeloLoiro, cabeloPreto,cabeloOutracor : inteiro

inicio


 escreval("Digite a letra do sexo: ")
 leia (sexo)
 
 se(sexo "F")
 escreval("A pessoa é do sexo feminino")
 
 se(sexo "M")
 escreval("A pessoa é do sexo masculino")
 
 
 escreval("Digite o numero da cor do cabelo: ")
 leia (corCabelo)
 
 se(corCabelo "1")
 escreval("A cor do cabelo é loiro: ")

 se(corCabelo "2")
 escreval("A cor do cabelo é preto: ")
 
 se(corCabelo "3")
 escreval("A cor do cabelo é outra: ")

 escreval("Deseja fazer mais uma pesquisa? Digite N para não ou S para sim")
 leia(pesquisa)
 
 sexoFeminino <- F
 sexoMasculino <- M
 cabeloLoiro <- 1
 cabelopreto <- 2
 cabeloOutracor <- 3
 sim <- S
 não <- N

 

[devair1010]

@Big_Big   seu código corrigido poderia ser assim  :

Algoritmo "Pesquisa3"
var
  // aqui são variáveis Globais , e podem ser acessadas de qualquer parte do
  // programa , até em outras funções e procedimentos , e são todas
  // inicializadas como valor zero
  pesquisa, sim, not, sexo, resp : caractere // variáveis não podem tem
                                             // acentuações e nem podem
                                             // ser palavras reservadas
                                             // e uma delas é essa "não"
                                             // outra é essa "e" "ou"
  sexoFeminino, sexoMasculino      : inteiro
  corCabelo, cabeloLoiro           : inteiro
  cabeloPreto,cabeloOutracor       : inteiro
  c_M_loiro, c_F_loira,c_outra_cor : inteiro
  c_M_preto, c_f_preto             : inteiro
inicio
  repita
    escreval("QuaL o sexo? [M/F] ")
    repita
      leia (sexo)
      se (sexo <> "m") e (sexo <> "f") entao // todo se precisa do entao e
                                             // do fimse e um operador
                                             // Lógico    =  <> > < not
         // repetir pois não digitou nem f e nem m
          escreval("digite novamente , apenas f  ou  m ")
      fimse
    ate (sexo = "f" ) ou (sexo = "m") // aqui precisa dos parenteses
                                      // pois são duas comparações
      se sexo = "f" entao // aqui não precisa dos parentesespois é
                          // apenas uma comparação e precisa desse "entao"
                          // sem acentuação
        escreval("A pessoa é do sexo feminino")
        sexofeminino <- sexofeminino + 1
      senao
        se sexo = "m" entao // precisa do sinal de igualdade e do entao
          escreval("A pessoa é do sexo masculino")
          sexomasculino <- sexomasculino + 1 // soma um a qtd de masculino
        fimse
      fimse

    escreval("QuaL a cor dos seus cabelos ? ")
    escreval("[1] loiro")
    escreval("[2] preto")
    escreval("[3] outra cor")
    repita    // só vai aceitar essas três opções  1  2  ou  3
      leia (corCabelo)
      se ( corcabelo < 1 ) ou ( corcabelo > 3 ) entao
        escreval("só pode 1 ou 2 ou 3 , digite novamente")
      fimse
    ate ( corcabelo > 0 ) e ( corcabelo < 4 )
    se corCabelo = 1 entao
      escreval("A cor do cabelo é loiro: ")
      se sexo = "f" entao
        c_F_loira <- c_F_loira + 1
      senao
        c_M_loiro <- c_M_loiro + 1
      fimse
    senao
      se corCabelo = 2 entao
        escreval("A cor do cabelo é preto: ")
        se sexo = "f" entao
          c_F_preto <- c_F_preto + 1
        senao
          c_M_preto <- c_M_preto + 1
        fimse
      senao
        se corCabelo = 3 entao
          escreval("A cor do cabelo não é loiro nem preto !")
          c_outra_cor <- c_outra_cor + 1
        fimse
      fimse
    fimse
    escreva("' Quer continuar ? S / N '")
    leia(resp)
  ate resp = "n"
  escreval("Quantidade de Homens   Loiros -----------------: ", c_m_loiro  )
  escreval("Quantidade de Mulheres Loiras -----------------: ", c_f_loira  )
  escreval("Quantidade de Homens de cabelos pretos --------: ", c_m_preto  )
  escreval("Quantidade de Mulheres de cabelos pretos ------: ", c_f_preto  )
  escreval("Quantidade de Pessoas de cabelos de outra cor -: ", c_outra_cor)
fimalgoritmo