VisualG Como fazer soma em While (Enquanto) no VisualG

[Drelius]

Olá, pessoal do Grupo. Boa noite a todos!!

 

Pessoal, estou com uma dúvida kkkk. Sou iniciante em programação e estou fazendo alguns exercícios da Web para ter mais lógica na programação.

Como faço para fazer a soma em while (Enquanto) no VisualG? Vou deixar o código. Se vocês puderem me ajudar, fico muito grato! 

 

Algoritmo "semnome"
//Faça um programa que leia 5 números e informe a soma e a média deles.

Var
   media : real
   valor, numeros, cont : inteiro
Inicio
   escreval("Digite 5 valores")

   enquanto (cont < 5) faca
      cont <- cont + 1
      leia(numeros)
      valor <- numeros + cont
      media <- valor / 2
   fimenquanto

   escreval("A media é: ",media)
   escreval("A soma dos valores é: ",valor)
Fimalgoritmo

 

Eu pensei que era desta forma. mas obviamente não está dando certo. 

[Ricardov]

Existem vários tipos de média. A média aritmética de 5 valores é a soma desses valores dividida por 5 e não por 2 como fez.

E a varivel valor tem que acumular a soma dos números:

valor <- numeros + valor

 

É boa pratica identar o código, use crtl + G. E acompanhe na tela do Visual G a alocação dos valores nas variáveis, na execução linha a linha.

 

[Drelius]

@Ricardov Cara, muito obrigado!! Vou começar a usar este comando para me ajudar. Novamente, muito obrigado!!!

 

[Simon Viegas]

Segue um exemplo para referência:

 

algoritmo "Soma e médias de 5 números"
//Faça um programa que leia 5 números e informe a soma e a média deles.
var
   cont : inteiro
   numero : inteiro
   soma : inteiro
   media : real
inicio
   soma <- 0
   cont <- 0 
   escreval("Digite 5 valores")

   enquanto (cont < 5) faca
      cont <- cont + 1
      leia(numero)
      soma <- soma + numero
   fimEnquanto

   media <- soma / 5
   escreval("A media é ", media:1:2)
   escreval("A soma dos valores é ", soma:1)
fimAlgoritmo

 

 

Utilizando repita:

   repita
      cont <- cont + 1
      leia(numero)
      soma <- soma + numero
   ate (cont >= 5)

 

 

Com para:

   para cont de 1 ate 5 faca
      leia(numero)
      soma <- soma + numero
   fimPara

 

Observe que enquanto é apenas uma estrutura de seleção, como o repita e o para. Quase* tudo que se faz com um, vai dar para fazer com o outro... apenas um é mais simples para cada contexto... neste caso, o para seria mais indicado, pois nele mesmo tem um contato.

 

* O Visual tem algumas limitações devido a bugs ou características mais limitadas, daí, tem coisas que não vai conseguir fazer com o para (como um loop infinito, por exemplo)