VisualG Como fazer Diferença e Divisão no VisualG ?

[Caiomqc]

Fiz um código de calculadora e não consegui fazer as operações de divisão e subtração no procedimento Calculo() preciso de ajuda

algoritmo "CALCULADORA C900"
var
   Quantidade,Contador:Inteiro
   Numeros,Soma,Diferenca,Produto,Quociente,Subtraendo:Real
   Resposta:caractere
Procedimento Menu()
Inicio
   Escreval(" --- CALCULADORA C900 ---")
   Escreval("===========================")
   Escreval(" --- MENU DE OPERAÇÕES ---")
   Escreval("[1] ==> | ADIÇÃO        |")
   Escreval("[2] ==> | SUBTRAÇÃO     |")
   Escreval("[3] ==> | MULTIPLICAÇÃO |")
   Escreval("[4] ==> | DIVISÃO       |")
   Escreval("[5] ==> | SAIR...       |")
FimProcedimento

Procedimento Calculo()
Inicio
   LimpaTela
   Escreval("=== DIGITE OS NUMEROS ===")
   Para Contador de 1 ate Quantidade faca
      Leia (Numeros)
      Escolha Resposta
      Caso "1"
         Soma := Soma + 1
      Caso "2"
         Subtraendo := Numeros
         Numeros := Diferenca
         Diferenca := Subtraendo - Numeros
      Caso "3"
         Produto := Produto * Numeros
      Caso "4"
         Quociente := Numeros / Quociente
      FimEscolha
      Contador := Contador + 1
   FimPara
FimProcedimento

Procedimento Resultado()
Inicio
   Escolha Resposta
   Caso "1"
      Escreva("A Soma das parcelas será de ",Soma)
   Caso "2"
      Escreva("A Diferença das parcelas será de ",Diferenca)
   Caso "3"
      Escreva("O Produto das parcelas será de ",Produto)
   Caso "4"
      Escreva("O Quociente das parcelas será de ",Quociente)
   OutroCaso
   FimEscolha
FimProcedimento
inicio
   Produto := 1
   Quociente := 1
   Menu()
   Leia (Resposta)
   Se (Resposta = "5")então
      Escreva("Resposta Inválida!")
fimalgoritmo
fimse
Escreval("== DIGITE A QUANTIDADE D/PARCELAS ==>(MIN:2)")
Leia (Quantidade)
Calculo()
Resultado()
fimalgoritmo

 

[Midori]

@Caiomqc Nenhuma dessas operações está pegando duas parcelas, por exemplo a + b = c, etc. No caso soma só está incrementando por 1; Na subtração vai dar zero porque só está pegando a diferença da variável Subtraendo (que recebe o valor do Numero) por Numero...; Na multiplicação faltou as duas parcelas e na divisão o dividendo é o Numero e o divisor (chamado de Quociente aí) é 1? Talvez o motivo de ter feito dessa forma seja questão de contexto, então se puder postar o enunciado vai ajudar.

[Caiomqc]

@Midori

Desenvolva um algoritmo intitulado "Calculadora C900" que permita realizar operações aritméticas em um conjunto de números informados pelo usuário. O programa deverá ser capaz de efetuar as operações de adição, subtração, multiplicação e divisão entre os números fornecidos. Além disso, oferece a opção de sair do programa. O usuário terá a possibilidade de inserir a quantidade de números a serem utilizados nas operações (no mínimo 2 números).

A calculadora contará com um menu de operações, exibindo as seguintes opções:

[1] - Realizar adição

[2] - Realizar subtração

[3] - Realizar multiplicação

[4] - Realizar divisão

[5] - Sair do programa

O programa solicitará ao usuário que informe a quantidade de parcelas (números) a serem utilizadas nas operações. Em seguida, para cada parcela, o usuário deverá inserir um número.

Após a entrada dos números e operações, a calculadora efetuará os cálculos conforme a operação escolhida. Ao final, apresentará os resultados das operações realizadas, indicando a soma das parcelas, a diferença entre as parcelas, o produto das parcelas ou o quociente das parcelas, dependendo da operação escolhida.

Caso o usuário selecione a opção [5], o programa exibirá uma mensagem de resposta inválida. O programa também valida que a quantidade de parcelas seja no mínimo 2.

Desenvolva o código de acordo com o enunciado e considere as estruturas de controle, procedimentos e variáveis descritas no algoritmo fornecido. Certifique-se de implementar as operações corretamente e apresentar os resultados de forma clara e coerente.

[Midori]

@Caiomqc Acho mais simples com função. Você pode passar a quantidade e o tipo de operação como argumento e retornar o resultado, p.ex,

 

Algoritmo "CALCULADORA C900"
Var
    Operacao:   Inteiro
    Quantidade: Inteiro

Funcao Calculo(Quantidade: Inteiro; Operacao: Inteiro): Real
Var
    Total:      Real
    Contador:   Inteiro
    Numero:     Inteiro
Inicio
    Leia(Total)
    Para Contador de 1 Ate Quantidade - 1 Faca
        Leia(Numero)
        Escolha Operacao
            Caso 1
                Total <- Total + Numero
            Caso 2
                Total <- Total - Numero
            Caso 3
                Total <- Total * Numero
            Caso 4
                Se(Numero <> 0) então
                    Total <- Total / Numero
                FimSe
        FimEscolha
    FimPara
    Retorne Total
FimFuncao

Inicio
    LimpaTela
    Escreval(" --- CALCULADORA C900 ---")
    Escreval("===========================")
    Escreval(" --- MENU DE OPERAÇÕES ---")
    Escreval("[1] ==> | ADIÇÃO        |")
    Escreval("[2] ==> | SUBTRAÇÃO     |")
    Escreval("[3] ==> | MULTIPLICAÇÃO |")
    Escreval("[4] ==> | DIVISÃO       |")
    Escreval("[5] ==> | SAIR...       |")
    Leia(Operacao)
    Escreva("Quantidade: ")
    Leia(Quantidade)
    Escreval("Resultado = ", Calculo(Quantidade, Operacao))
FimAlgoritmo

 

[Simon Viegas]

@Caiomqc, precisa também implementar as validações:

 

7 horas atrás, Caiomqc disse:

Caso o usuário selecione a opção [5], o programa exibirá uma mensagem de resposta inválida. O programa também valida que a quantidade de parcelas seja no mínimo 2.