VisualG Não consigo chamar o vetor no meu código

[Raí Machado Da Silva]

Olá, boa tarde! 

Estou escrevendo um código no VisualG e não consigo chamar o vetor do mesmo. Sempre que tento chamar o vetor ele retorna zero. Eis aqui abaixo a pergunta, espero que alguém possa me ajudar.

 

Crie um programa que preencha automaticamente (usando lógica, não apenas
atribuindo diretamente) um vetor numérico com 10 posições, conforme abaixo:
5 10 15 20 25 30 35 40 45 50
0 1 2 3 4 5 6 7 8 9

 

Agora vou postar o código que escrevi logo abaixo ...Caso eu chame o vetor no segundo Para (Onde tá circulado de verde) neste código ele só retorna 0, visto que, quero que ele retorne de 0 a 9.

Espero que alguém possa me ajudar.

algoritmo "PrenchendoVetores"
var

   V: Vetor[0..9] de Inteiro
   C, N: Inteiro

inicio
     
      Para C <- 5 Ate 50 Passo 5 Faca
           Escreva(C)
      FimPara
      Escreval()

      Para C <- 0 Ate 9 FacA

           Escreva(C," ")
      FimPara

fimalgoritmo

 

[Midori]

Faltou passar os números para o vetor. Aí só está pegando a variável C.

 

Uma forma simples de armazenar os valores pode ser assim,

 

Para C <- 0 Ate 9 Faca
   V[C] <- (C + 1) * 5
FimPara

 

[Raí Machado Da Silva]

@Midori Muito obrigado. Poderia me explicar o porque precisa fazer a multiplicação * 5?. Confesso que ainda não entendi..

[Ricardov]

@Raí Machado Da Silva  por que tem que preencher o vetor com múltiplos de cinco:

(0 + 1) * 5 = 5

(1 + 1) * 5 = 10

(2 + 1) * 5 = 15

etc.

 

 

[Raí Machado Da Silva]

Assim ficou o código que digitei após as dicas e explicações que recebi aqui. Estou muito agradecido @Ricardov e @Midori que me ajudaram. Espero que o código esteja certo. kkkkk

algoritmo "PrenchendoVetores2"
var

   V: Vetor[0..9] de Inteiro
   C: Inteiro

inicio

   Para C <- 0 Ate 9 Faca
      V[C] <- (C + 1) * 5
      Escreva(V[C], " ")
   FimPara
   Escreval()

   Para C <- 0 Ate 9 Faca
      V[C] <- C
      Escreva(V[C], "  ")
   FimPara

fimalgoritmo

 

[Midori]

@Raí Machado Da Silva O enunciado pede para armazenar múltiplos de 5 no vetor. Acho mais fácil dessa forma com o contador C como índice do vetor. Assim para pegar os múltiplos é só adicionar 1 ao contador e multiplicar por 5.

 

Outra forma poderia ser com tentou com a instrução Passo 5. Assim vai incrementar o contador de 5 em 5, aí para pegar o índice do vetor pode usar outra variável para incrementar de 1 em 1, p.ex,

 

N <- 0
Para C <- 5 Ate 50 Passo 5 Faca
   V[N] <- C
   N <- N + 1
FimPara

 

[Raí Machado Da Silva]

@Midori Entendi, muito obrigado. Sinto que vou aprender muito aqui com vocês.

[Simon Viegas]

Só um detalhe sobre essa exibição dos valores na tela:

 

O VisualG já insere automaticamente um espaço ANTES do número a ser impresso. Veja:

   Para C <- 0 Ate 9 Faca
      V[C] <- (C + 1) * 5
      Escreva(V[C])
   FimPara
   Escreval()

   Para C <- 0 Ate 9 Faca
      V[C] <- C
      Escreva(V[C])
   FimPara

 

"Pela lógica", os números sairiam todos colados, né? Mas na verdade saem assim:

 

Ou seja: no teu código os números serão impressos com 2 e 3 espaços, respectivamente, entre si, pois terá um a mais à esquerda. (E não com 1 e 2, que foi o que colocou lá!).

 

Caso queria imprimir sem esse espaço à esquerda, é possível utilizar um recurso de formatação. Veja:

   Para C <- 0 Ate 9 Faca
      V[C] <- (C + 1) * 5
      Escreva(V[C]:1, " ")
   FimPara
   Escreval()

   Para C <- 0 Ate 9 Faca
      V[C] <- C
      Escreva(V[C]:1, "  ")
   FimPara

 

 

Assim, ficou "colado à esquerda" e ficou com apenas 1 e 2 espações respectivamente. E claro, se remover esses espaços após a vírgula, sairiam tudo colado.

 

Como esses ":x" funciona? (Sendo x um número inteiro maior ou igual a zero, mas claro que terá uma limite...): basicamente ele vai definir "quantos espaços mínimos um número deve ocupar na tela, inserindo espaços à esquerda caso necessário". Pode ir fazendo testes com números diferentes e ir assimilando aos poucos. O detalhe é que, ao formatar com ":x", aquele tal "espaço automático à esquerda" é removido!!

 

Aí pode ir brincado com as possibilidades.