VisualG Tempo de espera e depois apagar

[Kayky Nascimento]

Estou fazendo um algoritmo de perguntas para um trabalho de biologia no qual tenho que fazer um jogo, Ele ficou assim, preciso colocar para o texto em baixo do leia(Nota1) Ficar 1 minuto depois limpar o chat do DDOS e ir para as perguntas tem como?
Preciso deixar o texto 1m pois o objetivo do jogo é que você consiga guardar os dados na sua memória para responder os questionários então a pessoa tem q ter uma boa atenção para conseguir absorver esse texto em 1 minuto e depois responder as perguntas, qualquer duvida deixa no chat
 

algoritmo "semnome"
// Função :
// Autor :
// Data : 28/07/2018
// Seção de Declarações 
var
nota1,nota2,nota,media:caractere
inicio
escreval("Seja Bem Vindo, O Objetivo desse jogo é testar seu conhecimento sobre enzimas")
escreval("|----------------------------------------------------------------------------------------------------------------")
escreval("|Participantes: Kayky, Ana Julia, Ana Luiza, Lorena, Manoel ")
escreval("|")
escreval("|Serão 5 perguntas e no final te daremos a nota, Boa Sorte!")
escreval("|")
escreval("|                                               * *")
escreval("|                                                u")
escreval("|-----------------------------------------------------------------------------------------------------------------")
escreval("aparecera um texto e você tera 1 minuto para ler e depois")
escreval("tera que responder algumas perguntas sobre Enzimas, você esta pronto? ")
escreval("")
escreval("Responda com Sim ou Não")
leia(nota1)
escreval("As enzimas são moléculas catalisadoras, presentes no organismo do ser humano")
escreval("formadas por proteínas. A principal função delas é favorecer o acontecimento de")
escreval("algumas reações biológicas, cada enzima é responsável por apenas um")
escreval("tipo de reação química, que são essenciais para a vida.")
escreval("o que São Enzimas ?")
leia(nota2)
escreval("Qual a principal função das Enzimas?")
leia(nota3)
fimalgoritmo

 

[Pedro Math.pi]

Boa tarde.

Acho que o timer funciona no visualG

 

http://www.ebah.com.br/content/ABAAAgmMoAA/visualg-versao-2-cronometro

http://www.apoioinformatica.inf.br/produtos/item/21-outros-comandos

[Simon Viegas]

7 horas atrás, Kayky Nascimento disse:

Estou fazendo um algoritmo de perguntas para um trabalho de biologia no qual tenho que fazer um jogo, Ele ficou assim, preciso colocar para o texto em baixo do leia(Nota1) Ficar 1 minuto depois limpar o chat do DDOS e ir para as perguntas tem como?
Preciso deixar o texto 1m pois o objetivo do jogo é que você consiga guardar os dados na sua memória para responder os questionários então a pessoa tem q ter uma boa atenção para conseguir absorver esse texto em 1 minuto e depois responder as perguntas, qualquer duvida deixa no chat

 

Então, a faixa limite do tal timer() é de 0 a 10000 milissegundos, ou seja, se quer que aguarde 1 minutos (o mesmo que 60 segundos, que é o mesmo que 60000 milissegundos) é necessário que, no mínimo, 6 instruções sejam executadas (se usar 10000). Ex.:

limpatela
escreval("As enzimas são moléculas catalisadoras, presentes no organismo do ")
escreval("ser humano, em sua maioria, formadas por proteínas. A principal   ")
escreval("função delas é favorecer o acontecimento de algumas reações bioló-")
escreval("gicas.")
escreval("")
escreval("Cada enzima é responsável por apenas um tipo de reação química,   ")
escreval("que são essenciais para a vida.                                   ")
//timer 10000 //cada instrução do programa vai arguardar X milissegundos para ser executada
timer 1000 //deixei 1s para facilitar os testes (não precisar esperar um minuto cada vez)
escreva("") //vai aguardar 10 para ser executar
escreva("") //20 (em relação ao tempo inicial)
escreva("") //30
escreva("") //40
escreva("") //50
timer 0     //60 reconfigura para não haver "tempo de travamento"
limpatela //ou seja, essa linha vai ser executada após 60 segundos
escreval("O que são enzimas ?")
leia(resposta1)
escreval("Qual a principal função das enzimas?")
leia(resposta1)

 

adicionado 21 minutos depois

Se precisar usar mais de uma vez... ou mesmo para organizar, poderia criar um procedimento, ex.:

procedimento espera60s()
   inicio
   timer 1000  //deixei 1s para facilitar os testes (não precisar esperar um minuto cada vez)
   escreva("") //vai aguardar 10 para ser executar
   escreva("") //20 (em relação ao tempo inicial)
   escreva("") //30
   escreva("") //40
   escreva("") //50
   timer 0     //60 reconfigura para não haver "tempo de travamento"
   fimProcedimento

 

...
escreval("que são essenciais para a vida.                                   ")
espera60s()
limpatela //ou seja, essa linha vai ser executada após 60 segundos
escreval("O que são enzimas ?")
...

 

adicionado 43 minutos depois

Outra forma:

procedimento espera60()
   var
      i :inteiro
   inicio
   //timer 500
   timer 50
   para i de 1 ate 60 faca
      escreva(".")
   fimPara
   timer 0 
   fimProcedimento

A ideia foi imprimir um "." a cada segundo. Como são duas instruções a cada loop, divide o tempo por 2.

[devair1010]

@Kayky Nascimento      o comando timer funciona bem , como o @Simon Viegas  disse , mas o timer faz a tela  ficar apresentando aquela barra azul na tela  se movendo para baixo e para cima ,  e creio que isso não seria interessante no seu jogo ,  então para evitar isso e a tela permanecer parada , você pode usar o comando para sem nada dentro dele  para perder tempo , então seu código com algumas modificações pode ser assim  :

algoritmo "jogo_perguntas"
// Função :
// Autor :
// Data : 28/07/2018
// Seção de Declarações
var
  nota1,nota2,nota3,media : caractere
procedimento pausar
var
  x,j,tempo_de_espera : inteiro
inicio
  escreva("")
  tempo_de_espera:=100000  //tempo de espera = 30 segundos
  escreva("Tempo ->")
  escreva(" .")
  escreva("")
  para j de 0 ate tempo_de_espera faca
    x := x+1
    se x > 10000 ENTÃO
      x := 0
      escreva(" .")
      escreva("")
    fimse
  fimpara
  escreval
  escreva("Digite A Resposta . . . !  ")
fimprocedimento
inicio
  escreval("Seja Bem Vindo, O Objetivo desse jogo é testar seu conhecimento sobre enzimas")
  escreval("|----------------------------------------------------------------------------------------------------------------")
  escreval("|Participantes: Kayky, Ana Julia, Ana Luiza, Lorena, Manoel ")
  escreval("|")
  escreval("|Serão 5 perguntas e no final te daremos a nota, Boa Sorte!")
  escreval("|")
  escreval("|                                               * *")
  escreval("|                                                u")
  escreval("|-----------------------------------------------------------------------------------------------------------------")
  escreval("aparecera um texto e você tera 1 minuto para ler e depois")
  escreval("tera que responder algumas perguntas sobre Enzimas, você esta pronto? ")
  escreval("")
  escreval("Responda com Sim ou Não")
  pausar
  leia(nota1)
  limpatela
  escreval("As enzimas são moléculas catalisadoras, presentes no organismo do ser humano")
  escreval("formadas por proteínas. A principal função delas é favorecer o acontecimento de")
  escreval("algumas reações biológicas, cada enzima é responsável por apenas um")
  escreval("tipo de reação química, que são essenciais para a vida.")
  escreval("o que São Enzimas ?")
  pausar
  leia(nota2)
  escreval("Qual a principal função das Enzimas?")
  pausar
  leia(nota3)
fimalgoritmo