VisualG Criar um programa em Visualg que permita o cadastro de produtos

[HenriqueArisi]

Bom, sou universitário de ADS e nossa linguagem de aprendizagem por enquanto é o portugol do Visualg.

Tenho uma dúvida em um algoritmo que fiz.

O algoritmo consiste em: 

Criar um programa em Visualg que permita o cadastro de produtos com NOME, CÓDIGO E VALOR.

E a pesquisa de produtos por código. O programa deve retornar as informações do produto encontrado, ou uma mensagem de erro se o produto não for encontrado.

 

Aqui está o código...

 

algoritmo "Cadastro e Pesquisa de Produtos"
var
   nome: vetor[1..50] de caractere
   codigo: vetor[1..100] de inteiro
   valor: vetor[1..100] de real
   opcao: caractere
   codigoPesquisa: inteiro
   encontrado: logico
   quantidadeProdutos: inteiro
   i: inteiro

procedimento cadastrarProduto
inicio
   se quantidadeProdutos < 100 então

      escreval("Digite o nome do produto: ")
      leia(nome[quantidadeProdutos])
      escreva("Digite o código do produto: ")
      leia(codigo[quantidadeProdutos])
      escreva("Digite o valor do produto: ")
      leia(valor[quantidadeProdutos])

      quantidadeProdutos <- quantidadeProdutos + 1
      escreva("Produto cadastrado com sucesso!")
   senao
      escreval("Limite de produtos atingido. Não é possível cadastrar mais produtos.")
   fimse
fimprocedimento


procedimento pesquisarProduto
inicio
   encontrado <- falso
   para i de 0 ate quantidadeProdutos-1 faca
      se codigo[i] = codigoPesquisa então
         escreval("Produto encontrado:")
         escreval("Nome: ", nome[i])
         escreval("Código: ", codigo[i])
         escreval("Valor: ", valor[i])
         encontrado <- verdadeiro
         interrompa
      fimse
   fimpara
   se não encontrado então
      escreval("Produto não encontrado.")
   fimse
fimprocedimento

inicio
   quantidadeProdutos <- 0

   repita
      escreval("========== Menu ==========")
      escreval("1 - Cadastrar Produto")
      escreval("2 - Pesquisar Produto por Código")
      escreval("S - Sair")
      escreval("==========================")
      escreva("Escolha a opção desejada: ")
      leia(opcao)

      escolha opcao
      caso "1"
         cadastrarProduto

      caso "2"
         se quantidadeProdutos > 0 então
            escreva("Digite o código do produto a ser pesquisado: ")
            leia(codigoPesquisa)
            pesquisarProduto(quantidadeProdutos)
         senao
            escreval("Nenhum produto cadastrado.")
         fimse

      caso "S"
         escreval("Saindo do programa.")
      outrocaso
         escreval("Opção inválida. Tente novamente.")
      fimescolha
   ate opcao = "S"
fimalgoritmo

Fiz com estruturas de procedimento e escolha caso, que é o que estamos aprendendo no momento. O erro se dá na hora de escolher a opção 1 - Cadastrar produto

Não sei sé é necessário todas essas prints, mas é tudo o que o Visualg acusa, e sei q nem sempre o que ele acusa é o que esta incorreto! mas já fiz de tudo que eu consigo pensar para arrumar isso 
Espero que os experts possam me ajudar, desde já, obrigado!

 

 

 

 

Henrique Arisi 23.11.2023

[Simon Viegas]

Em 23/11/2023 às 02:46, HenriqueArisi disse:

sei q nem sempre o que ele acusa é o que esta incorreto!

 

Sim..., mas comece pelo que foi informado.

 

 

Em 23/11/2023 às 02:46, HenriqueArisi disse:

 

Está dizendo que não foi encontrada a posição 0 do vetor nome.

 

Em 23/11/2023 às 02:46, HenriqueArisi disse:

nome: vetor[1..50] de caractere

 

Como visto, não existe a posição 0.

 

Só corrigir:

procedimento cadastrarProduto ()
inicio
   se (quantidadeProdutos < 100) então
      quantidadeProdutos <- quantidadeProdutos+1
      escreva ("Digite o nome do produto: ")
      leia(nome[quantidadeProdutos])
      escreva ("Digite o código do produto: ")
      leia(codigo[quantidadeProdutos])
      escreva ("Digite o valor do produto: ")
      leia(valor[quantidadeProdutos])
      escrevaL("Produto cadastrado com sucesso!")
   senao
      escrevaL("Limite de produtos atingido. Não é possível cadastrar mais produtos.")
   fimse
fimProcedimento